1 files changed, 72 insertions, 0 deletions
diff --git a/dev-scheme/guile-git/guile-git-0.6.0-r1.ebuild b/dev-scheme/guile-git/guile-git-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..7bf4dc097034
--- /dev/null
+++ b/dev-scheme/guile-git/guile-git-0.6.0-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Guile bindings of git"
+HOMEPAGE="https://gitlab.com/guile-git/guile-git/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://gitlab.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/${PN}/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	S="${WORKDIR}/${PN}-v${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+
+# Works without sandbox. But under sandbox sshd claims to break the protocol.
+RESTRICT="test"
+
+# older libgit seems to be incompatible with guile-git bindings
+# https://github.com/trofi/nix-guix-gentoo/issues/7
+RDEPEND="
+	>=dev-libs/libgit2-1:=
+	>=dev-scheme/guile-2.0.11:=
+	dev-scheme/bytestructures
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# guile is trying to avoid recompilation by checking if file
+	#     /usr/lib64/guile/2.2/site-ccache/<foo>
+	# is newer than
+	#     <foo>
+	# In case it is instead of using <foo> guile
+	# loads system one (from potentially older version of package).
+	# To work it around we bump last modification timestamp of
+	# '*.scm' files.
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_test() {
+	emake check VERBOSE=1
+}
+
+src_install() {
+	default
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}