1 files changed, 39 insertions, 0 deletions
diff --git a/dev-ruby/ruby-feedparser/ruby-feedparser-0.9.6.ebuild b/dev-ruby/ruby-feedparser/ruby-feedparser-0.9.6.ebuild
new file mode 100644
index 000000000000..bcaa2442bb43
--- /dev/null
+++ b/dev-ruby/ruby-feedparser/ruby-feedparser-0.9.6.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_EXTRADOC="ChangeLog.md README"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+GITHUB_USER="feed2imap"
+
+DESCRIPTION="Ruby library to parse ATOM/RSS feeds"
+HOMEPAGE="https://github.com/feed2imap/ruby-feedparser"
+SRC_URI="https://github.com/${GITHUB_USER}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE=""
+
+ruby_add_rdepend "dev-ruby/magic"
+
+ruby_add_bdepend "dev-ruby/magic
+	test? ( dev-ruby/mocha )"
+
+all_ruby_prepare() {
+	# Extract gemspec source from Rakefile
+	sed -n -e '/Gem::Specification/,/end$/p' Rakefile > ${RUBY_FAKEGEM_GEMSPEC} || die
+	sed -i -e 's/PKG_NAME/"'${PN}'"/' \
+		-e 's/PKG_VERSION/"'${PV}'"/' \
+		-e '/s.files/d' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+each_ruby_prepare() {
+	sed -i -e '/PKG_VERSION/ s:ruby:'${RUBY}':' Rakefile || die
+}