1 files changed, 49 insertions, 0 deletions
diff --git a/dev-ruby/http/http-4.4.1.ebuild b/dev-ruby/http/http-4.4.1.ebuild
new file mode 100644
index 000000000000..1b3a4d077041
--- /dev/null
+++ b/dev-ruby/http/http-4.4.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An easy-to-use client library for making requests from Ruby"
+HOMEPAGE="https://github.com/tarcieri/http"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "
+	>=dev-ruby/addressable-2.3:0
+	>=dev-ruby/http-cookie-1.0:0
+	>=dev-ruby/http-form_data-2.2:2
+	=dev-ruby/http-parser-1.2*"
+
+ruby_add_bdepend "
+	test? ( dev-ruby/certificate_authority dev-ruby/rspec-its )"
+
+all_ruby_prepare() {
+	sed -i -e '/simplecov/,/end/ s:^:#:' \
+		-e '1irequire "cgi"' spec/spec_helper.rb || die
+
+	# Avoid specs that require network access
+	sed -i -e '/.persistent/,/^  end/ s:^:#:' \
+		spec/lib/http_spec.rb || die
+	sed -i -e '/with non-ASCII URLs/,/^    end/ s:^:#:' \
+		spec/lib/http/client_spec.rb || die
+
+	# Avoid spec that may fail with a running web server
+	sed -i -e '/unifies socket errors into HTTP::ConnectionError/,/^  end/ s:^:#:' spec/lib/http_spec.rb || die
+
+	# Fix spec for production release
+	sed -i -e '/User-Agent:/ s/.dev//' spec/lib/http/features/logging_spec.rb || die
+
+	# Avoid specs also failing upstream due to some certificate issue
+	sed -i -e '/context "ssl"/,/^      end/ s:^:#:' spec/lib/http_spec.rb || die
+	sed -i -e '/describe "working with SSL"/,/^  end/ s:^:#:' spec/lib/http/client_spec.rb || die
+}