1 files changed, 57 insertions, 0 deletions
diff --git a/dev-python/wcmatch/wcmatch-8.3.ebuild b/dev-python/wcmatch/wcmatch-8.3.ebuild
new file mode 100644
index 000000000000..61d6e0564f4d
--- /dev/null
+++ b/dev-python/wcmatch/wcmatch-8.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	~dev-python/mkdocs_pymdownx_material_extras-1.0.7
+	dev-python/mkdocs-material
+	dev-python/mkdocs-git-revision-date-localized-plugin
+	dev-python/mkdocs-minify-plugin
+	dev-python/pyspelling
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="Wildcard/glob file name matcher"
+HOMEPAGE="
+	https://github.com/facelessuser/wcmatch/
+	https://pypi.org/project/wcmatch/"
+SRC_URI="https://github.com/facelessuser/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/backrefs-4.1[${PYTHON_USEDEP}]
+	>=dev-python/bracex-2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# tests require some files in homedir
+	> "${HOME}"/test1.txt || die
+	> "${HOME}"/test2.txt || die
+
+	# mkdocs-git-revision-date-localized-plugin needs git repo
+	if use doc; then
+		git init || die
+		git config --global user.email "you@example.com" || die
+		git config --global user.name "Your Name" || die
+		git add . || die
+		git commit -m 'init' || die
+	fi
+
+	distutils-r1_python_prepare_all
+}