1 files changed, 63 insertions, 0 deletions
diff --git a/dev-python/vdirsyncer/vdirsyncer-0.18.0-r1.ebuild b/dev-python/vdirsyncer/vdirsyncer-0.18.0-r1.ebuild
new file mode 100644
index 000000000000..21d72fd5f54a
--- /dev/null
+++ b/dev-python/vdirsyncer/vdirsyncer-0.18.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="Synchronize calendars and contacts"
+HOMEPAGE="https://github.com/pimutils/vdirsyncer"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="dev-python/click[${PYTHON_USEDEP}]
+	>=dev-python/click-log-0.3.0[${PYTHON_USEDEP}]
+	<dev-python/click-log-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/click-threading-0.5[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	dev-python/atomicwrites[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pytest-subtesthack[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.18.0-no-cov.patch"
+)
+
+DOCS=( AUTHORS.rst CHANGELOG.rst CONTRIBUTING.rst README.rst config.example )
+
+distutils_enable_tests pytest
+
+python_test() {
+	# skip tests needing servers running
+	local -x DAV_SERVER=skip
+	local -x REMOTESTORAGE_SERVER=skip
+	# pytest dies hard if the envvars do not have any value...
+	local -x CI=false
+	local -x DETERMINISTIC_TESTS=false
+
+	local deselect=(
+		# test CA is too weak for modern python
+		tests/system/utils/test_main.py::test_request_ssl
+		tests/system/utils/test_main.py::test_request_ssl_fingerprints
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	systemd_dounit contrib/vdirsyncer.{service,timer}
+}