1 files changed, 54 insertions, 0 deletions
diff --git a/dev-python/trio/trio-0.19.0.ebuild b/dev-python/trio/trio-0.19.0.ebuild
new file mode 100644
index 000000000000..14417d4fa8a4
--- /dev/null
+++ b/dev-python/trio/trio-0.19.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio
+	https://pypi.org/project/trio
+"
+SRC_URI="https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/async_generator-1.9[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		>=dev-python/jedi-0.18.0[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pylint[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+distutils_enable_sphinx docs/source \
+					dev-python/immutables \
+					dev-python/sphinxcontrib-trio \
+					dev-python/sphinx_rtd_theme \
+					dev-python/towncrier
+
+python_prepare_all() {
+	# these tests require internet access
+	rm trio/tests/test_ssl.py || die
+	rm trio/tests/test_highlevel_ssl_helpers.py || die
+
+	distutils-r1_python_prepare_all
+}