1 files changed, 39 insertions, 0 deletions
diff --git a/dev-python/seaborn/seaborn-0.10.0.ebuild b/dev-python/seaborn/seaborn-0.10.0.ebuild
new file mode 100644
index 000000000000..ede4b500f025
--- /dev/null
+++ b/dev-python/seaborn/seaborn-0.10.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Statistical data visualization"
+HOMEPAGE="https://seaborn.pydata.org https://github.com/mwaskom/seaborn"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/matplotlib-2.1.2[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.13.3[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.22.0[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	dev-python/statsmodels[${PYTHON_USEDEP}]
+	>=sci-libs/scipy-1.0.1[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	cat > matplotlibrc <<- EOF || die
+	backend : Agg
+	EOF
+	virtx nosetests --verbosity=3
+}