1 files changed, 0 insertions, 72 deletions
diff --git a/dev-python/requests/requests-2.28.0-r1.ebuild b/dev-python/requests/requests-2.28.0-r1.ebuild
deleted file mode 100644
index b96762bee446..000000000000
--- a/dev-python/requests/requests-2.28.0-r1.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
-EAPI=7
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..11} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1
-
-DESCRIPTION="HTTP library for human beings"
-HOMEPAGE="
-	https://requests.readthedocs.io/
-	https://github.com/psf/requests/
-	https://pypi.org/project/requests/
-"
-SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-IUSE="socks5"
-
-RDEPEND="
-	>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
-	dev-python/charset_normalizer[${PYTHON_USEDEP}]
-	<dev-python/idna-4[${PYTHON_USEDEP}]
-	<dev-python/urllib3-1.27[${PYTHON_USEDEP}]
-	socks5? ( >=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}] )
-"
-
-BDEPEND="
-	test? (
-		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
-		!alpha? ( !hppa? ( !ia64? (
-			dev-python/trustme[${PYTHON_USEDEP}]
-		) ) )
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-2.28.0-unpin-charset-normalizer.patch
-)
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Internet (doctests)
-		requests/__init__.py::requests
-		requests/api.py::requests.api.request
-		requests/models.py::requests.models.PreparedRequest
-		requests/sessions.py::requests.sessions.Session
-		# require IPv4 interface in 10.* range
-		tests/test_requests.py::TestTimeout::test_connect_timeout
-		tests/test_requests.py::TestTimeout::test_total_timeout_connect
-		# TODO: openssl?
-		tests/test_requests.py::TestRequests::test_pyopenssl_redirect
-	)
-
-	if ! has_version "dev-python/trustme[${PYTHON_USEDEP}]"; then
-		EPYTEST_DESELECT+=(
-			tests/test_requests.py::TestRequests::test_https_warnings
-		)
-	fi
-
-	epytest
-}