1 files changed, 33 insertions, 0 deletions
diff --git a/dev-python/rencode/rencode-1.0.6-r1.ebuild b/dev-python/rencode/rencode-1.0.6-r1.ebuild
new file mode 100644
index 000000000000..f02c970bbcdc
--- /dev/null
+++ b/dev-python/rencode/rencode-1.0.6-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="similar to bencode from the BitTorrent project"
+HOMEPAGE="https://github.com/aresch/rencode"
+SRC_URI="https://github.com/aresch/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	# https://github.com/aresch/rencode/commit/16e61e1ff4294bddb7c881536d3d454355c78969
+	"${FILESDIR}/${P}-drop-wheel-dependency.patch"
+)
+
+python_test() {
+	# The C extension ("_rencode") can't be imported from "${S}/rencode"
+	# so we need to cd somewhere else to make sure "rencode" is imported
+	# from ${BUILD_DIR}/lib (thanks to PYTHONPATH).
+	cd "${T}" || die
+	epytest "${S}"
+}