1 files changed, 60 insertions, 0 deletions
diff --git a/dev-python/pylint/pylint-2.3.1.ebuild b/dev-python/pylint/pylint-2.3.1.ebuild
new file mode 100644
index 000000000000..7e1e963e3a5d
--- /dev/null
+++ b/dev-python/pylint/pylint-2.3.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="https://www.logilab.org/project/pylint
+	https://pypi.org/project/pylint/
+	https://github.com/pycqa/pylint"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc64 ~sparc ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	>=dev-python/astroid-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	dev-python/mccabe[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.3.1-sphinx-theme.patch"
+	"${FILESDIR}/${PN}-2.3.1-no-pytest-runner.patch"
+)
+
+python_compile_all() {
+	# selection of straight html triggers a trivial annoying bug, we skirt it
+	use doc && PYTHONPATH="${S}" emake -e -C doc singlehtml
+}
+
+python_test() {
+	${EPYTHON} -m pytest -v pylint/test/ || die "tests failed"
+}
+
+python_install_all() {
+	doman man/{pylint,pyreverse}.1
+	if use examples ; then
+		docinto examples
+		dodoc -r examples/.
+	fi
+	use doc && local HTML_DOCS=( doc/_build/singlehtml/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	# Optional dependency on "tk" USE flag would break support for Jython.
+	optfeature "pylint-gui script requires dev-lang/python with \"tk\" USE flag enabled." 'dev-lang/python[tk]'
+}