1 files changed, 79 insertions, 0 deletions
diff --git a/dev-python/poetry-core/poetry-core-1.6.1.ebuild b/dev-python/poetry-core/poetry-core-1.6.1.ebuild
new file mode 100644
index 000000000000..304711f93c75
--- /dev/null
+++ b/dev-python/poetry-core/poetry-core-1.6.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..12} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+DESCRIPTION="Poetry PEP 517 Build Backend"
+HOMEPAGE="
+	https://github.com/python-poetry/poetry-core/
+	https://pypi.org/project/poetry-core/
+"
+SRC_URI="
+	https://github.com/python-poetry/poetry-core/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# check inside src/poetry/core/_vendor/vendor.txt
+# (note that some are indirect deps)
+RDEPEND="
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lark[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}/${P}-pypy3.patch"
+)
+
+EPYTEST_DESELECT=(
+	# These "fail" bacause of glob file path resulting from newer versions
+	# in our tree than vendored. But those don't affect anything.
+	tests/masonry/builders/test_sdist.py::test_default_with_excluded_data
+	tests/masonry/builders/test_wheel.py::test_default_src_with_excluded_data
+)
+
+src_prepare() {
+	# remove vendoring of dependencies
+	rm -r src/poetry/core/_vendor || die
+	sed -e '/__vendor_site__/d' -i src/poetry/core/__init__.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
+		einfo "Skippin tests on ${EPYTHON} (unported deps)"
+		return
+	fi
+
+	# needed for migration from <1.1
+	distutils_write_namespace poetry
+	epytest
+}