2 files changed, 108 insertions, 0 deletions
diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index 0b67b67a64d8..b2217f04f825 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1,6 +1,8 @@
 AUX plotly-5.8.0-fix-versioneer-import.patch 541 BLAKE2B 51ff6cbab8d9124243445f758aa4b976b7c26e1d3ce633e943bff133b81c0a7587feeb9d5e98a63f319c6afed8dc06e06fafe765ffd51fec245215c849fb4955 SHA512 db4743e538dddfe66e4c9c766698844af4d09c68188afefe92b6419adfe7cc0b1e9c1266d702d590b0b8dfc14bffbc8f08262ead0bff4dae3b5c71fa1259a4b9
 DIST plotly.py-5.13.1.gh.tar.gz 30629767 BLAKE2B 818fc888f8bc15b2dc95557363214c69fa3cbba6c973cfde02c1b9a718cdaaa22e03a95e8d5876003bc12bece3460d50216395b94d503516ceed6c836dd1675d SHA512 75b57d212e9c1e277c9136a30e95e2d1d64049fb719c9c97646760b69a2ff61576db0b8e06eed799552e9388bdb9459720030d027d466cb88fec38492b61c79b
 DIST plotly.py-5.14.0.gh.tar.gz 30697515 BLAKE2B 53c17d418cacc7da6783b5ac1b1212a9d2e1cb957a196a398dcdd9185829389592a428ca7b173f4ad78c59171336cbb15efc0b35a46581bc9206fbd2a302b3bc SHA512 c36610d3bb6e0f0f2c25cb06672bbcb16adc83f4203b7ec0a79b18a04e20bed26bcc253d8082e4d4dca63f0253a8c0143e65e006e52f9044be6b526994857d8c
+DIST plotly.py-5.14.1.gh.tar.gz 30697895 BLAKE2B 2fd602b353cf6097f3b0341cdd07b82fe38181a2c2cf21a7a7fe3b88c65160ac0b1a000bad9eca540754570f0b06b746f286f2a7bc89dfdd4454356165b6ded9 SHA512 cf053ea47425ad4f4f1412ce8ba037f49609a292b61afaa63bd8c00f010353f56a648cded408b9788055e2bba69e6a71192b55602d11d4122dc76e6dd3085a11
 EBUILD plotly-5.13.1.ebuild 3100 BLAKE2B f65adcad42d0a8325673f9fb99d954eb41216839092d036a5ca7330bf2d395c18572adb6d57d0c8a7f8312a0671a815bacbad73112708b3857d7a3f0a924a62b SHA512 b2b17cee89f06b8a946fe07d84e6d57cbb02e33a0cb231a5f21de0cebc35e97a96fc9c946bd3119c108097b35e8a30214cf28403eb6366a683536735256f5d99
 EBUILD plotly-5.14.0.ebuild 3025 BLAKE2B 2502ee70dbf2c994e3472eea16199281c89bb7118428d417342bc05729e41e674e417576602c80f8c7a33d11bb94838430c8c4aae5850651bb67cc1e84e94f42 SHA512 d60723f83828fa2c55671e052536d6fe15887779819b704dc1bd2c29fcc3de6a6b24aa75e25e4a27af38c759dc2b2fb9841e7fd1e3bf4284cabcba26d9da45e3
+EBUILD plotly-5.14.1.ebuild 3025 BLAKE2B 2502ee70dbf2c994e3472eea16199281c89bb7118428d417342bc05729e41e674e417576602c80f8c7a33d11bb94838430c8c4aae5850651bb67cc1e84e94f42 SHA512 d60723f83828fa2c55671e052536d6fe15887779819b704dc1bd2c29fcc3de6a6b24aa75e25e4a27af38c759dc2b2fb9841e7fd1e3bf4284cabcba26d9da45e3
 MISC metadata.xml 627 BLAKE2B 453adb04f4caba9790fe5223635245c8bca7ca5c6dc1930f09537045580b88b5fa1649e47158b13be6cc5cb09b4479a47690e37ef13208b47a95f82d14793a91 SHA512 a5183e9d217d1312e8d383ccb4ade66b92575492b6c8ed8987e3af18e9e456836b62b2d572ce62f9e01aae47b4a2bcbd12f79b4bb6acabfe69c2b63b20315bd3
diff --git a/dev-python/plotly/plotly-5.14.1.ebuild b/dev-python/plotly/plotly-5.14.1.ebuild
new file mode 100644
index 000000000000..760cd2ec5a69
--- /dev/null
+++ b/dev-python/plotly/plotly-5.14.1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_P=plotly.py-${PV}
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="
+	https://plotly.com/python/
+	https://github.com/plotly/plotly.py/
+	https://pypi.org/project/plotly/
+"
+SRC_URI="
+	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/packages/python/plotly"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-6.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+		sci-libs/scikit-image[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.8.0-fix-versioneer-import.patch
+)
+
+EPYTEST_IGNORE=(
+	# Needs porting to newer numpy
+	_plotly_utils/tests/validators/test_integer_validator.py
+
+	# kaleido not packaged
+	plotly/tests/test_optional/test_kaleido
+
+	# plotly-orca not packaged
+	plotly/tests/test_orca
+)
+
+EPYTEST_DESELECT=(
+	# Also needs porting to newer numpy
+	plotly/tests/test_io/test_to_from_plotly_json.py::test_object_numpy_encoding
+
+	# kaleido not packaged
+	plotly/tests/test_orca/test_to_image.py::test_bytesio
+
+	# Fails if not already installed
+	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+	test_init/test_lazy_imports.py::test_lazy_imports
+
+	# Minor matplotlib incompatibility
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_path_collection
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+	# In python 3.11 the produced error is slightly different
+	plotly/tests/test_core/test_errors/test_dict_path_errors.py::test_described_subscript_error_on_type_error
+)
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	mv "${ED}"/{usr/etc,etc} || die
+}