1 files changed, 49 insertions, 0 deletions
diff --git a/dev-python/path-py/path-py-15.0.1.ebuild b/dev-python/path-py/path-py-15.0.1.ebuild
new file mode 100644
index 000000000000..ee2c52e7b643
--- /dev/null
+++ b/dev-python/path-py/path-py-15.0.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+inherit distutils-r1
+
+MY_P="path-${PV}"
+
+DESCRIPTION="A module wrapper for os.path"
+HOMEPAGE="https://pypi.org/project/path/ https://github.com/jaraco/path"
+SRC_URI="mirror://pypi/p/path/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	!<dev-python/pytest-shutil-1.7.0-r1
+	!<dev-python/pytest-virtualenv-1.7.0-r1"
+BDEPEND="
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# avoid a setuptools_scm dependency
+	sed -e "s/setup_requires = setuptools_scm/version = '${PV}'/" \
+		-i setup.cfg || die
+
+	# disable fancy test deps
+	sed -e 's: --flake8:: ; s: --black:: ; s: --cov:: ; s: --mypy::' \
+		-i pytest.ini || die
+
+	# fragile test for import time
+	sed -i -e 's:test_import_time:_&:' test_path.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	PYTHONPATH=. pytest -vv || die
+}