1 files changed, 55 insertions, 0 deletions
diff --git a/dev-python/jeepney/jeepney-0.7.1.ebuild b/dev-python/jeepney/jeepney-0.7.1.ebuild
new file mode 100644
index 000000000000..e68d7065e154
--- /dev/null
+++ b/dev-python/jeepney/jeepney-0.7.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( pypy3 python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, pure Python DBus protocol wrapper"
+HOMEPAGE="https://gitlab.com/takluyver/jeepney"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="examples"
+
+BDEPEND="
+	test? (
+		dev-python/async_timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		sys-apps/dbus
+		$(python_gen_cond_dep '
+			dev-python/pytest-trio[${PYTHON_USEDEP}]
+			dev-python/trio[${PYTHON_USEDEP}]
+		' python3_{8..9})
+	)
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+python_test() {
+	local ignore=()
+	# keep in sync with python_gen_cond_dep!
+	if ! has "${EPYTHON}" python3.{8..9}; then
+		ignore+=( jeepney/io/tests/test_trio.py )
+	fi
+
+	dbus-run-session pytest -vv -ra -l ${ignore[@]/#/--ignore } ||
+		die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}