1 files changed, 41 insertions, 0 deletions
diff --git a/dev-python/ipy/ipy-1.01.ebuild b/dev-python/ipy/ipy-1.01.ebuild
new file mode 100644
index 000000000000..a8260ce8a9d2
--- /dev/null
+++ b/dev-python/ipy/ipy-1.01.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+MY_PN="IPy"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Class and tools for handling of IPv4 and IPv6 addresses and networks"
+HOMEPAGE="https://github.com/autocracy/python-ipy/wiki https://pypi.org/project/IPy/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="examples"
+
+python_test() {
+	# 1 test fail under pypy, persistent from 0.82a, not a regression.
+	cp -r test_doc.py README.rst test "${BUILD_DIR}" || die
+	pushd "${BUILD_DIR}" > /dev/null || die
+	"${PYTHON}" test/test_IPy.py || die "Tests fail with ${EPYTHON}"
+	"${PYTHON}" test_doc.py || die "Doctests fail with ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}