1 files changed, 52 insertions, 0 deletions
diff --git a/dev-python/future/future-0.16.0-r1.ebuild b/dev-python/future/future-0.16.0-r1.ebuild
new file mode 100644
index 000000000000..03ae068da381
--- /dev/null
+++ b/dev-python/future/future-0.16.0-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Easy, clean, reliable Python 2/3 compatibility"
+HOMEPAGE="http://python-future.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~amd64-fbsd ~x86-linux"
+IUSE="doc test"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-bootstrap-theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	# https://github.com/PythonCharmers/python-future/issues/165
+	"${FILESDIR}/${P}-disable-tests-with-internet-connection.patch"
+	# https://github.com/PythonCharmers/python-future/pull/355
+	"${FILESDIR}/${P}-fix-tests-py37.patch"
+)
+
+python_prepare_all() {
+	sed -i "/'sphinx.ext.intersphinx'/d" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs/ docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	pytest -vv || die "Tests failed under ${EPYTHON}"
+}