1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/django-sortedm2m/django-sortedm2m-3.1.1-r2.ebuild b/dev-python/django-sortedm2m/django-sortedm2m-3.1.1-r2.ebuild
new file mode 100644
index 000000000000..4c0c11c3e205
--- /dev/null
+++ b/dev-python/django-sortedm2m/django-sortedm2m-3.1.1-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Drop-in replacement for django's many to many field with sorted relations"
+HOMEPAGE="
+	https://pypi.org/project/django-sortedm2m/
+	https://github.com/jazzband/django-sortedm2m/
+"
+SRC_URI="
+	https://github.com/jazzband/django-sortedm2m/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/django-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+	)
+"
+
+python_test() {
+	local -x PYTHONPATH=test_project:${PYTHONPATH}
+	local -x DB_ENGINE=sqlite3
+	local -x DB_NAME=":memory:"
+	django-admin test -v 2 --settings=settings --noinput sortedm2m_tests ||
+		die "Tests fail with ${EPYTHON}"
+}