1 files changed, 0 insertions, 74 deletions
diff --git a/dev-python/django-cacheops/django-cacheops-7.0-r1.ebuild b/dev-python/django-cacheops/django-cacheops-7.0-r1.ebuild
deleted file mode 100644
index 2f101f8d547e..000000000000
--- a/dev-python/django-cacheops/django-cacheops-7.0-r1.ebuild
+++ /dev/null
@@ -1,74 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} )
-
-inherit distutils-r1
-
-DESCRIPTION="ORM cache with automatic granular event-driven invalidation for Django"
-HOMEPAGE="
-	https://github.com/Suor/django-cacheops/
-	https://pypi.org/project/django-cacheops/
-"
-SRC_URI="
-	https://github.com/Suor/django-cacheops/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/django-3.2[${PYTHON_USEDEP}]
-	>=dev-python/redis-2.9.1[${PYTHON_USEDEP}]
-	>=dev-python/funcy-1.8[${PYTHON_USEDEP}]
-	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		${RDEPEND}
-		dev-db/redis
-		dev-python/dill[${PYTHON_USEDEP}]
-		dev-python/mock[${PYTHON_USEDEP}]
-	)
-"
-
-src_prepare() {
-	# Remove test dependent on unpackaged before_after
-	sed -e 's/test_lock/_&/' -i tests/test_extras.py || die
-	# Remove upper bounds on dependencies
-	sed -i -e 's:,<[0-9]*::' setup.py || die
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	local -x DJANGO_SETTINGS_MODULE=tests.settings
-	local -x PYTHONPATH=.
-	django-admin test -v 2 || die
-}
-
-src_test() {
-	local redis_pid="${T}"/redis.pid
-	local redis_port=6379
-
-	einfo "Spawning Redis"
-	einfo "NOTE: Port ${redis_port} must be free"
-	"${EPREFIX}"/usr/sbin/redis-server - <<-EOF || die
-		daemonize yes
-		pidfile ${redis_pid}
-		port ${redis_port}
-		bind 127.0.0.1
-	EOF
-
-	# Run the tests
-	distutils-r1_src_test
-
-	# Clean up afterwards
-	kill "$(<"${redis_pid}")" || die
-}