1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/confuse/confuse-1.0.0.ebuild b/dev-python/confuse/confuse-1.0.0.ebuild
new file mode 100644
index 000000000000..716e4d492632
--- /dev/null
+++ b/dev-python/confuse/confuse-1.0.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Confuse is a configuration library for Python that uses YAML"
+HOMEPAGE="https://github.com/beetbox/confuse"
+SRC_URI="https://github.com/beetbox/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		rm -r docs/_build/html/_sources || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests failed"
+	if use doc; then
+		sphinx-build -W -q -b html docs __doctest || die "Doc tests failed"
+	fi
+}