1 files changed, 41 insertions, 0 deletions
diff --git a/dev-libs/yajl/yajl-2.0.4-r3.ebuild b/dev-libs/yajl/yajl-2.0.4-r3.ebuild
new file mode 100644
index 000000000000..b0670a2bb73b
--- /dev/null
+++ b/dev-libs/yajl/yajl-2.0.4-r3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils cmake-multilib vcs-snapshot
+
+DESCRIPTION="Small event-driven (SAX-style) JSON parser"
+HOMEPAGE="https://lloyd.github.com/yajl/"
+SRC_URI="https://github.com/lloyd/yajl/tarball/${PV} -> ${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-fix_static_linking.patch
+	"${FILESDIR}"/${P}-pkgconfig_multilib.patch
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	multilib_copy_sources
+}
+
+src_test() {
+	run_test() {
+		cd "${BUILD_DIR}"/test
+		./run_tests.sh ./yajl_test || die
+	}
+	multilib_parallel_foreach_abi run_test
+}
+
+src_install() {
+	cmake-multilib_src_install
+
+	use static-libs || \
+		find "${D}" -name libyajl_s.a -delete
+}