1 files changed, 42 insertions, 0 deletions
diff --git a/dev-libs/roct-thunk-interface/roct-thunk-interface-9999.ebuild b/dev-libs/roct-thunk-interface/roct-thunk-interface-9999.ebuild
new file mode 100644
index 000000000000..4860c47142d2
--- /dev/null
+++ b/dev-libs/roct-thunk-interface/roct-thunk-interface-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils linux-info
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/RadeonOpenCompute/ROCT-Thunk-Interface/"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/RadeonOpenCompute/ROCT-Thunk-Interface/archive/roc-${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/ROCT-Thunk-Interface-roc-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Radeon Open Compute Thunk Interface"
+HOMEPAGE="https://github.com/RadeonOpenCompute/ROCT-Thunk-Interface"
+CONFIG_CHECK="~HSA_AMD ~HMM_MIRROR ~ZONE_DEVICE"
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+
+RDEPEND="sys-process/numactl
+	sys-apps/pciutils"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	sed -e "s:get_version ( \"1.0.0\" ):get_version ( \"${PV}\" ):" -i CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+src_configure() {
+	local mycmakeargs=(
+		-DCPACK_PACKAGING_INSTALL_PREFIX=/usr
+	)
+	cmake-utils_src_configure
+}
+src_compile() {
+	cmake-utils_src_compile build-dev
+}
+src_install() {
+	cmake-utils_src_install install-dev
+}