1 files changed, 41 insertions, 0 deletions
diff --git a/dev-libs/mpc/mpc-1.3.0-r1.ebuild b/dev-libs/mpc/mpc-1.3.0-r1.ebuild
new file mode 100644
index 000000000000..58311b7a2ead
--- /dev/null
+++ b/dev-libs/mpc/mpc-1.3.0-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+DESCRIPTION="A library for multiprecision complex arithmetic with exact rounding"
+HOMEPAGE="https://www.multiprecision.org/mpc/ https://gitlab.inria.fr/mpc/mpc"
+
+if [[ ${PV} == *_rc* ]] ; then
+	SRC_URI="https://www.multiprecision.org/downloads/${P/_}.tar.gz"
+	S="${WORKDIR}"/${P/_}
+else
+	SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0/3" # libmpc.so.3
+IUSE="static-libs"
+
+DEPEND="
+	>=dev-libs/gmp-5.0.0:=[${MULTILIB_USEDEP},static-libs?]
+	>=dev-libs/mpfr-4.1.0:=[${MULTILIB_USEDEP},static-libs?]
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-header.patch
+)
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}