1 files changed, 58 insertions, 0 deletions
diff --git a/dev-libs/libxmlb/libxmlb-0.1.15-r1.ebuild b/dev-libs/libxmlb/libxmlb-0.1.15-r1.ebuild
new file mode 100644
index 000000000000..36625e4a84a0
--- /dev/null
+++ b/dev-libs/libxmlb/libxmlb-0.1.15-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Library to help create and query binary XML blobs"
+HOMEPAGE="https://github.com/hughsie/libxmlb"
+SRC_URI="https://github.com/hughsie/libxmlb/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+KEYWORDS="amd64 ~arm ~arm64 x86"
+IUSE="doc introspection stemmer test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	sys-apps/util-linux
+	stemmer? ( dev-libs/snowball-stemmer:= )
+"
+
+DEPEND="
+	${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/meson-0.47.0
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	has_version -b "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgtkdoc="$(usex doc true false)"
+		-Dintrospection="$(usex introspection true false)"
+		-Dstemmer="$(usex stemmer true false)"
+		-Dtests="$(usex test true false)"
+	)
+	meson_src_configure
+}