1 files changed, 0 insertions, 222 deletions
diff --git a/dev-lang/rust-bin/rust-bin-1.63.0.ebuild b/dev-lang/rust-bin/rust-bin-1.63.0.ebuild
deleted file mode 100644
index b265137db4d1..000000000000
--- a/dev-lang/rust-bin/rust-bin-1.63.0.ebuild
+++ /dev/null
@@ -1,222 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit multilib prefix rust-toolchain toolchain-funcs verify-sig multilib-minimal
-
-MY_P="rust-${PV}"
-# curl -L static.rust-lang.org/dist/channel-rust-${PV}.toml 2>/dev/null | grep "xz_url.*rust-src"
-MY_SRC_URI="${RUST_TOOLCHAIN_BASEURL%/}/2022-08-11/rust-src-${PV}.tar.xz"
-GENTOO_BIN_BASEURI="https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}" # omit leading slash
-
-DESCRIPTION="Systems programming language from Mozilla"
-HOMEPAGE="https://www.rust-lang.org/"
-SRC_URI="$(rust_all_arch_uris ${MY_P})
-	rust-src? ( ${MY_SRC_URI} )
-"
-# Keep this separate to allow easy commenting out if not yet built
-SRC_URI+=" sparc? ( ${GENTOO_BIN_BASEURI}/${MY_P}-sparc64-unknown-linux-gnu.tar.xz ) "
-
-LICENSE="|| ( MIT Apache-2.0 ) BSD-1 BSD-2 BSD-4 UoI-NCSA"
-SLOT="stable"
-KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-IUSE="clippy cpu_flags_x86_sse2 doc prefix rls rust-src rustfmt"
-
-DEPEND=""
-
-RDEPEND="
-	>=app-eselect/eselect-rust-20190311
-	sys-apps/lsb-release
-"
-
-BDEPEND="
-	prefix? ( dev-util/patchelf )
-	verify-sig? ( sec-keys/openpgp-keys-rust )
-"
-
-REQUIRED_USE="x86? ( cpu_flags_x86_sse2 )"
-
-QA_PREBUILT="
-	opt/${P}/bin/.*
-	opt/${P}/lib/.*.so
-	opt/${P}/libexec/.*
-	opt/${P}/lib/rustlib/.*/bin/.*
-	opt/${P}/lib/rustlib/.*/lib/.*
-"
-
-# An rmeta file is custom binary format that contains the metadata for the crate.
-# rmeta files do not support linking, since they do not contain compiled object files.
-# so we can safely silence the warning for this QA check.
-QA_EXECSTACK="opt/${P}/lib/rustlib/*/lib*.rlib:lib.rmeta"
-
-VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/rust.asc"
-
-pkg_pretend() {
-	if [[ "$(tc-is-softfloat)" != "no" ]] && [[ ${CHOST} == armv7* ]]; then
-		die "${CHOST} is not supported by upstream Rust. You must use a hard float version."
-	fi
-}
-
-src_unpack() {
-	# sadly rust-src tarball does not have corresponding .asc file
-	# so do partial verification
-	if use verify-sig; then
-		for f in ${A}; do
-			if [[ -f ${DISTDIR}/${f}.asc ]]; then
-				verify-sig_verify_detached "${DISTDIR}/${f}" "${DISTDIR}/${f}.asc"
-			fi
-		done
-	fi
-
-	default_src_unpack
-
-	mv "${WORKDIR}/${MY_P}-$(rust_abi)" "${S}" || die
-}
-
-patchelf_for_bin() {
-	local filetype=$(file -b ${1})
-	if [[ ${filetype} == *ELF*interpreter* ]]; then
-		einfo "${1}'s interpreter changed"
-		patchelf ${1} --set-interpreter ${2} || die
-	elif [[ ${filetype} == *script* ]]; then
-		hprefixify ${1}
-	fi
-}
-
-multilib_src_install() {
-	if multilib_is_native_abi; then
-
-	# start native abi install
-	pushd "${S}" >/dev/null || die
-	local analysis std
-	analysis="$(grep 'analysis' ./components)"
-	std="$(grep 'std' ./components)"
-	local components="rustc,cargo,${std}"
-	use doc && components="${components},rust-docs"
-	use clippy && components="${components},clippy-preview"
-	use rls && components="${components},rls-preview,${analysis}"
-	use rustfmt && components="${components},rustfmt-preview"
-	# Rust component 'rust-src' is extracted from separate archive
-	if use rust-src; then
-		einfo "Combining rust and rust-src installers"
-		mv -v "${WORKDIR}/rust-src-${PV}/rust-src" "${S}" || die
-		echo rust-src >> ./components || die
-		components="${components},rust-src"
-	fi
-	./install.sh \
-		--components="${components}" \
-		--disable-verify \
-		--prefix="${ED}/opt/${P}" \
-		--mandir="${ED}/opt/${P}/man" \
-		--disable-ldconfig \
-		|| die
-
-	if use prefix; then
-		local interpreter=$(patchelf --print-interpreter ${EPREFIX}/bin/bash)
-		ebegin "Changing interpreter to ${interpreter} for Gentoo prefix at ${ED}/opt/${P}/bin"
-		find "${ED}/opt/${P}/bin" -type f -print0 | \
-			while IFS=  read -r -d '' filename; do
-				patchelf_for_bin ${filename} ${interpreter} \; || die
-			done
-		eend $?
-	fi
-
-	local symlinks=(
-		cargo
-		rustc
-		rustdoc
-		rust-gdb
-		rust-gdbgui
-		rust-lldb
-	)
-
-	use clippy && symlinks+=( clippy-driver cargo-clippy )
-	use rls && symlinks+=( rls )
-	use rustfmt && symlinks+=( rustfmt cargo-fmt )
-
-	einfo "installing eselect-rust symlinks and paths"
-	local i
-	for i in "${symlinks[@]}"; do
-		# we need realpath on /usr/bin/* symlink return version-appended binary path.
-		# so /usr/bin/rustc should point to /opt/rust-bin-<ver>/bin/rustc-<ver>
-		local ver_i="${i}-bin-${PV}"
-		ln -v "${ED}/opt/${P}/bin/${i}" "${ED}/opt/${P}/bin/${ver_i}"
-		dosym "../../opt/${P}/bin/${ver_i}" "/usr/bin/${ver_i}"
-	done
-
-	# symlinks to switch components to active rust in eselect
-	dosym "../../../opt/${P}/lib" "/usr/lib/rust/lib-bin-${PV}"
-	dosym "../../../opt/${P}/man" "/usr/lib/rust/man-bin-${PV}"
-	dosym "../../opt/${P}/lib/rustlib" "/usr/lib/rustlib-bin-${PV}"
-	dosym "../../../opt/${P}/share/doc/rust" "/usr/share/doc/${P}"
-
-	# musl logic can be improved a bit, but fine as is for now
-	cat <<-_EOF_ > "${T}/50${P}"
-	LDPATH="${EPREFIX}/usr/lib/rust/lib"
-	MANPATH="${EPREFIX}/usr/lib/rust/man"
-	$(use amd64 && usex elibc_musl 'CARGO_TARGET_X86_64_UNKNOWN_LINUX_MUSL_RUSTFLAGS="-C target-feature=-crt-static"' '')
-	$(use arm64 && usex elibc_musl 'CARGO_TARGET_AARCH64_UNKNOWN_LINUX_MUSL_RUSTFLAGS="-C target-feature=-crt-static"' '')
-	_EOF_
-	doenvd "${T}/50${P}"
-
-	# note: eselect-rust adds EROOT to all paths below
-	cat <<-_EOF_ > "${T}/provider-${P}"
-	/usr/bin/cargo
-	/usr/bin/rustdoc
-	/usr/bin/rust-gdb
-	/usr/bin/rust-gdbgui
-	/usr/bin/rust-lldb
-	/usr/lib/rustlib
-	/usr/lib/rust/lib
-	/usr/lib/rust/man
-	/usr/share/doc/rust
-	_EOF_
-
-	if use clippy; then
-		echo /usr/bin/clippy-driver >> "${T}/provider-${P}"
-		echo /usr/bin/cargo-clippy >> "${T}/provider-${P}"
-	fi
-	if use rls; then
-		echo /usr/bin/rls >> "${T}/provider-${P}"
-	fi
-	if use rustfmt; then
-		echo /usr/bin/rustfmt >> "${T}/provider-${P}"
-		echo /usr/bin/cargo-fmt >> "${T}/provider-${P}"
-	fi
-
-	insinto /etc/env.d/rust
-	doins "${T}/provider-${P}"
-	popd >/dev/null || die
-	#end native abi install
-
-	else
-		local rust_target
-		rust_target="$(rust_abi $(get_abi_CHOST ${v##*.}))"
-		dodir "/opt/${P}/lib/rustlib"
-		cp -vr "${WORKDIR}/rust-${PV}-${rust_target}/rust-std-${rust_target}/lib/rustlib/${rust_target}"\
-			"${ED}/opt/${P}/lib/rustlib" || die
-	fi
-
-	# BUG: installs x86_64 binary on other arches
-	rm -f "${ED}/opt/${P}/lib/rustlib/"*/bin/rust-llvm-dwp || die
-}
-
-pkg_postinst() {
-	eselect rust update
-
-	elog "Rust installs a helper script for calling GDB now,"
-	elog "for your convenience it is installed under /usr/bin/rust-gdb-bin-${PV}."
-
-	if has_version app-editors/emacs; then
-		elog "install app-emacs/rust-mode to get emacs support for rust."
-	fi
-
-	if has_version app-editors/gvim || has_version app-editors/vim; then
-		elog "install app-vim/rust-vim to get vim support for rust."
-	fi
-}
-
-pkg_postrm() {
-	eselect rust cleanup
-}