4 files changed, 161 insertions, 14 deletions
diff --git a/dev-java/swt/Manifest b/dev-java/swt/Manifest
index d3aab2a5a425..c1b64c1a1693 100644
--- a/dev-java/swt/Manifest
+++ b/dev-java/swt/Manifest
@@ -16,7 +16,8 @@ DIST swt-3.8.2-gtk-linux-x86.zip 5558694 BLAKE2B 8dd0ce9f2c6b8dc448c85a6c509f39e
 DIST swt-3.8.2-gtk-linux-x86_64.zip 5865160 BLAKE2B 45d60d334eb99f407cf9101a06f65e48543538a386103767700fb0af5ea0cf3da73eefe57b8cc6b3d78cb8f29345869f5474513648560395a69cbd4c9b8ee8a4 SHA512 43a27cb6fc891d7da35f5fcfc6ccb689d2b2c58de70b628b1e7cf07131f0641598b627eeedafb6a8dca715a336a7fb4fb6a03bb29fea3e115a4af571b1574cf8
 DIST swt-4.10-gtk-linux-ppc64le.zip 3848264 BLAKE2B 214861fde6987906fb24f3187936f3bcb49aebed54fe242427c3737bf6761e8f77d049c376f30ca0fc33e74a1e8a48b6aff6d9863775ee9c33fea7cb2edd1309 SHA512 1b3ede58c2b41abae76f58a303bd3fbf1849ba8be3fd6518325bc22400e960c3ab542e7351b1bc08053e2746ea3e28812e04c2d1789cb1e19ea28745c8a5f39a
 DIST swt-4.10-gtk-linux-x86_64.zip 3844306 BLAKE2B 0e0ed21708acce347fd025920ee635f586c460f8a9c05a7067fd70eed9da999b4a62a5febd17f0c5546ab15198336038e4ab49a1bd588d49ffb39450353a1911 SHA512 9dd946cb7c11446f553f06b8af516167519bab00d4a89f626cd612be6d18e50023fc537aa3d844a8f7a56a767df00410efe4dd20e2bfd930639330a1e279a7a0
-EBUILD swt-3.7.2-r3.ebuild 4437 BLAKE2B f488c4f50f7019580f29cbbc374d440444a699934193db8f6251d76c2342c5a26a5b65cc7c993ffb90155f771bc9039075b6a202c06d98abbdf7a2ff5959f63a SHA512 afdf8e0de244d457b4aa857bc1f045d0a3aa304158ece0a147c7b20308a27c79b5f614dd7ab0143c4372f7155679019cd972ab28a997cd9fe666f0d2985ea21b
-EBUILD swt-3.8.2-r3.ebuild 4240 BLAKE2B 3c08a0ee771d859e07af9d01c9796571ec9295bc0be4058abb330bd62194f20c77744795fcd27412a7397e7a341b7556080d3a7589faa9548ab1f1ac97433005 SHA512 f5c8f79cb9c801062d21d17f6ccdc30b28d5d1716e63ecae00872fce2c7c1b8a6152882ab90ddf6a39d4f525429462415cef6597a9425ec59060d6d0fdbe5099
+EBUILD swt-3.7.2-r3.ebuild 4364 BLAKE2B 8c238643fbcdbb8c3536a6ba3b931ddca6dcf1593cd987893f71f025ca90f8fb539b2a20b9d06e0a984e49966c368d8be51f8a7e1483cf4365a5e90aca840083 SHA512 f78cb150abf666a4b48ee5a1f926c36c88db2cefc69a02151b49ee0a9b31f22bbf635594e28168483a7691e8b4a53f57c7bad689d8c8f90d850e34434e2520ec
+EBUILD swt-3.8.2-r3.ebuild 4167 BLAKE2B 9ecd08f8b5604aacc7d662e221bfac8b40267957dc1d61ea6da93efe4fd94a8de9799842f59d32a872a5706f84ffce8f1f5300e9f604fcb27991a1124a724b58 SHA512 ed61b6ad2899efe069df78d6b798efc755c78bfdef9dc1939346dbf6c110e6b8719c173a2480a55a2df52fa88cd130e7d77f72e6c905e4a00a7438d9b4319682
+EBUILD swt-3.8.2-r4.ebuild 4161 BLAKE2B f49d7e6ffed9da09772c8ae6a3a9588c21e405ee7963cd0ee32562b4b62bac16fb497e559fc1d99bab5c495bb285737aabaa042038dc0bcd47aabc8b6c977f84 SHA512 60bdc6cdcf9f6bf230ca1482e4f65c1d6843c65b02ac008bf970b80f4f900b0cbba74a27fc4591b50e4dd891f319a2484f318fff18db9239dde0431132320c37
 EBUILD swt-4.10-r2.ebuild 4527 BLAKE2B 9f2d0c3eb9bf1903c9f14376a31d4e7e9e7dd0122dc4f8938f4bc38bf8bec5aaeb9257d90c3259257f666f48257176f9a98dd5ea10201a793a6c36a4b305ac61 SHA512 1aa4bba24a5dabcc1173cea8bf930a380eabab23ac26b89a564e683d711287fd6811bdfa7b114480951c914f4a533b4c8c9fda4db6f7377ee2074b1764e3c06c
 MISC metadata.xml 519 BLAKE2B 5c132bb4b8d9fbacfae3262a550e34932088ecbd204c3a8c2c13d782b0b0fa37a3b255bc84c388ee13f874b427a87a4321e605d0c614308300c18715c9631ab5 SHA512 ef81d6d7cc9f8e2309dcb8bdd78ea942a7a300ba4ed8506a93f12150c9142a5f62a153c0d77e3000f78637d5523367b7fce1186bbac01cafae10d4d0af6c959d
diff --git a/dev-java/swt/swt-3.7.2-r3.ebuild b/dev-java/swt/swt-3.7.2-r3.ebuild
index 24e69a974015..12ccd36700f1 100644
--- a/dev-java/swt/swt-3.7.2-r3.ebuild
+++ b/dev-java/swt/swt-3.7.2-r3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -108,11 +108,7 @@ src_compile() {
 	# Fix the pointer size for AMD64
 	[[ ${ARCH} == "amd64" || ${ARCH} == "ppc64" ]] && export SWT_PTR_CFLAGS=-DJNI64
 
-	local platform="linux"
-
-	use elibc_FreeBSD && platform="freebsd"
-
-	local make="emake -f make_${platform}.mak NO_STRIP=y CC=$(tc-getCC) CXX=$(tc-getCXX)"
+	local make="emake -f make_linux.mak NO_STRIP=y CC=$(tc-getCC) CXX=$(tc-getCXX)"
 
 	einfo "Building AWT library"
 	${make} make_awt
diff --git a/dev-java/swt/swt-3.8.2-r3.ebuild b/dev-java/swt/swt-3.8.2-r3.ebuild
index d65297c3817c..604916b2de09 100644
--- a/dev-java/swt/swt-3.8.2-r3.ebuild
+++ b/dev-java/swt/swt-3.8.2-r3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="5"
@@ -99,11 +99,7 @@ src_compile() {
 	# Fix the pointer size for AMD64
 	[[ ${ARCH} == "amd64" || ${ARCH} == "ppc64" ]] && export SWT_PTR_CFLAGS=-DJNI64
 
-	local platform="linux"
-
-	use elibc_FreeBSD && platform="freebsd"
-
-	local make="emake -f make_${platform}.mak NO_STRIP=y CC=$(tc-getCC) CXX=$(tc-getCXX)"
+	local make="emake -f make_linux.mak NO_STRIP=y CC=$(tc-getCC) CXX=$(tc-getCXX)"
 
 	einfo "Building AWT library"
 	${make} make_awt
diff --git a/dev-java/swt/swt-3.8.2-r4.ebuild b/dev-java/swt/swt-3.8.2-r4.ebuild
new file mode 100644
index 000000000000..341e66a35938
--- /dev/null
+++ b/dev-java/swt/swt-3.8.2-r4.ebuild
@@ -0,0 +1,154 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-pkg-2 java-ant-2 toolchain-funcs java-osgi
+
+MY_PV="${PV/_rc/RC}"
+MY_DMF="http://archive.eclipse.org/eclipse/downloads/drops/R-${MY_PV}-201301310800"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="GTK based SWT Library"
+HOMEPAGE="http://www.eclipse.org/"
+SRC_URI="
+	amd64? ( ${MY_DMF}/${MY_P}-gtk-linux-x86_64.zip )
+	ppc? ( ${MY_DMF}/${MY_P}-gtk-linux-x86.zip )
+	ppc64? ( ${MY_DMF}/${MY_P}-gtk-linux-ppc64.zip )
+	x86? ( ${MY_DMF}/${MY_P}-gtk-linux-x86.zip )
+	x86-fbsd? ( ${MY_DMF}/${MY_P}-gtk-linux-x86.zip )"
+
+LICENSE="CPL-1.0 LGPL-2.1 MPL-1.1"
+SLOT="3.8"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="cairo opengl"
+
+COMMON_DEPEND="
+	>=dev-libs/atk-1.10.2
+	>=dev-libs/glib-2.6
+	>=x11-libs/gtk+-2.6.8:2
+	x11-libs/libXtst
+	cairo? ( >=x11-libs/cairo-1.4.14 )
+	opengl? (
+		virtual/glu
+		virtual/opengl
+	)"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	virtual/jdk:1.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+	x11-libs/libX11
+	x11-libs/libXrender
+	x11-libs/libXt
+	>=x11-libs/libXtst-1.1.0"
+RDEPEND="${COMMON_DEPEND}
+	>=virtual/jre-1.4"
+
+S="${WORKDIR}"
+
+# JNI libraries don't need SONAME, bug #253756
+QA_SONAME="usr/lib.*/libswt-.*.so"
+
+PATCHES=(
+	"${FILESDIR}"/swt-3.8-as-needed-and-flag-fixes.patch
+	"${FILESDIR}"/swt-3.8.2-gthread.patch
+)
+
+src_unpack() {
+	local DISTFILE=${A}
+	unzip -jq "${DISTDIR}"/${DISTFILE} "*src.zip" || die "Unable to extract distfile"
+	unpack "./src.zip"
+
+	# Cleanup the redirtied directory structure
+	rm -rf about_files/ || die
+}
+
+src_prepare() {
+	default
+	# Replace the build.xml to allow compilation without Eclipse tasks
+	cp "${FILESDIR}/build.xml" "${S}/build.xml" || die "Unable to update build.xml"
+
+	mkdir -p "${S}/src"
+	mv "${S}/org" "${S}/src" || die "Unable to restructure SWT sources"
+}
+
+src_compile() {
+	# Drop jikes support as it seems to be unfriendly with SWT
+	java-pkg_filter-compiler jikes
+
+	local AWT_ARCH
+	local JAWTSO="libjawt.so"
+	if [[ $(tc-arch) == 'x86' ]] ; then
+		AWT_ARCH="i386"
+	elif [[ $(tc-arch) == 'ppc' ]] ; then
+		AWT_ARCH="ppc"
+	elif [[ $(tc-arch) == 'ppc64' ]] ; then
+		AWT_ARCH="ppc64"
+	else
+		AWT_ARCH="amd64"
+	fi
+	if [[ -f "${JAVA_HOME}/jre/lib/${AWT_ARCH}/${JAWTSO}" ]]; then
+		export AWT_LIB_PATH="${JAVA_HOME}/jre/lib/${AWT_ARCH}"
+	elif [[ -f "${JAVA_HOME}/jre/bin/${JAWTSO}" ]]; then
+		export AWT_LIB_PATH="${JAVA_HOME}/jre/bin"
+	elif [[ -f "${JAVA_HOME}/$(get_libdir)/${JAWTSO}" ]] ; then
+		export AWT_LIB_PATH="${JAVA_HOME}/$(get_libdir)"
+	else
+		eerror "${JAWTSO} not found in the JDK being used for compilation!"
+		die "cannot build AWT library"
+	fi
+
+	# Fix the pointer size for AMD64
+	[[ ${ARCH} == "amd64" || ${ARCH} == "ppc64" ]] && export SWT_PTR_CFLAGS=-DJNI64
+
+	local make="emake -f make_linux.mak NO_STRIP=y CC=$(tc-getCC) CXX=$(tc-getCXX)"
+
+	einfo "Building AWT library"
+	${make} make_awt
+
+	einfo "Building SWT library"
+	${make} make_swt
+
+	einfo "Building JAVA-AT-SPI bridge"
+	${make} make_atk
+
+	if use cairo ; then
+		einfo "Building CAIRO support"
+		${make} make_cairo
+	fi
+
+	if use opengl ; then
+		einfo "Building OpenGL component"
+		${make} make_glx
+	fi
+
+	einfo "Building JNI libraries"
+	eant compile
+
+	einfo "Copying missing files"
+	cp -i "${S}/version.txt" "${S}/build/version.txt" || die
+	cp -i "${S}/src/org/eclipse/swt/internal/SWTMessages.properties" \
+		"${S}/build/org/eclipse/swt/internal/" || die
+
+	einfo "Packing JNI libraries"
+	eant jar
+}
+
+src_install() {
+	swtArch=${ARCH}
+	use amd64 && swtArch=x86_64
+	use x86-fbsd && swtArch=x86
+
+	sed "s/SWT_ARCH/${swtArch}/" "${FILESDIR}/${PN}-${SLOT}-manifest" > "MANIFEST_TMP.MF" || die
+	use cairo || sed -i -e "/ org.eclipse.swt.internal.cairo; x-internal:=true,/d" "MANIFEST_TMP.MF"
+	sed -i -e "/ org.eclipse.swt.internal.gnome; x-internal:=true,/d" "MANIFEST_TMP.MF"
+	use opengl || sed -i -e "/ org.eclipse.swt.internal.opengl.glx; x-internal:=true,/d" "MANIFEST_TMP.MF"
+	sed -i -e "/ org.eclipse.swt.internal.webkit; x-internal:=true,/d" "MANIFEST_TMP.MF"
+	java-osgi_newjar-fromfile "swt.jar" "MANIFEST_TMP.MF" "Standard Widget Toolkit for GTK 2.0"
+
+	java-pkg_sointo /usr/$(get_libdir)
+	java-pkg_doso *.so
+
+	dodoc about.html
+}