3 files changed, 115 insertions, 0 deletions
diff --git a/dev-ada/Manifest.gz b/dev-ada/Manifest.gz
index 9bd87746232e..d127e5df96b8 100644
--- a/dev-ada/Manifest.gz
+++ b/dev-ada/Manifest.gz
diff --git a/dev-ada/gnatcoll-bindings/Manifest b/dev-ada/gnatcoll-bindings/Manifest
index 6905f83397e7..4f4a4cab2628 100644
--- a/dev-ada/gnatcoll-bindings/Manifest
+++ b/dev-ada/gnatcoll-bindings/Manifest
@@ -1,4 +1,6 @@
 AUX gnatcoll-bindings-23.0.0-py_3_11.patch 412 BLAKE2B 3d327f02b5305a7e0aa5414ec83be80ae62b6a2b93581846acf6306a3ab364c8ae07137bdffea1fce69a51c6bfa707daa0555ae49b7e69db0301c227896836ff SHA512 2539d5d96ec00cccef5b42fe5795d5cedffc528bb9e4d328007718f5189c61657cc77daf80a5f7da0a157c482e7146116ab6da8a9dd10afe68e1a3f30e3c548d
 DIST gnatcoll-bindings-24.0.0.tar.gz 253286 BLAKE2B 6f9ee60a298f98921df3f8bfd3c6e21a3b54412dfea3d67cb6fe0e85d7ba90f17f83d564d9853e989cd60b0d9d9052694a14a70d10a4f70d161878501edd036b SHA512 d82f593cd0a2822d0007ba768a05e9870aa80b47232154008ea91af4ec758df1b23b92eb5264a58f2b4bedf775d143ce7119046a9ba8f7d5496ed89f3a4a2118
+DIST gnatcoll-bindings-25.0.0.tar.gz 299443 BLAKE2B 8feee477728f036d32b4957ffde309d529eb5ccead784dd1bfaf7a3b945046672467ed3eac49336369bda473f317d30ce73f2d6a8afcbb289da4a4f7496f523a SHA512 0cc5b4a1e966b6e05dcfa15e60cb3960894ffe73b9348f0642a972f4d517e535c617893a4080d33095ee62779b14aeb6cdd8a8f0a8b5a6c8e81c94df132420b2
 EBUILD gnatcoll-bindings-24.0.0-r1.ebuild 2541 BLAKE2B a298d268e14f8f498dae13998e5f6cc034ed5cb499861e67ddd52551b33a7c7d98f758d0696fc8df51f74c6ec43cb25f8333dc9e9b491378f25ddab5ca2a3596 SHA512 b0b1ee319aa5f8f2e0bf718d7049e76764cfc5bcd1b5fe39280efa47b7703573f3425bc7a529d53bf0181a0729f4fafd21a7ade1e6b56f09ff981284d078073b
+EBUILD gnatcoll-bindings-25.0.0.ebuild 2984 BLAKE2B 1a4f4f8170153dbd8890ffbd9d442eda50bda533533046a913a517ae60995cec272a1b21c055613d400ad64a0cdf54388129f88f8439cc94b69d6dc1b03142df SHA512 e8770599765887e085ad5517b921728f4ed2974be3024865b529d66d3700265a4c9a9da81520d62dda3125e96f2465de55349c60ce99e5edb2741528cbfd0775
 MISC metadata.xml 1172 BLAKE2B 23758b9a71c24a6e635488947a6491713dd69750c62715b1fe0eb12db380d1ecc80ebb4941a00a9ae01ce2009316849e802560bc52402fed64b671547951cf89 SHA512 1ea356da231ee9b42df8733e0ca6c3cbb5e3a2f0eb143bc894a8961e82b69f2e05b0f5d8dba309dc6b0556c4340bb51175fe9aa5a272aae006eed4a2cf449098
diff --git a/dev-ada/gnatcoll-bindings/gnatcoll-bindings-25.0.0.ebuild b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-25.0.0.ebuild
new file mode 100644
index 000000000000..f3bc30e005e7
--- /dev/null
+++ b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-25.0.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+ADA_COMPAT=( gcc_13 gcc_14 )
+inherit ada multiprocessing python-single-r1
+
+DESCRIPTION="GNAT Component Collection"
+HOMEPAGE="https://github.com/AdaCore/gnatcoll-bindings/"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc gmp lzma openmp +shared static-libs static-pic"
+REQUIRED_USE="|| ( shared static-libs static-pic )
+	${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	${ADA_DEPS}
+	dev-ada/gnatcoll-core:${SLOT}[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	gmp? ( dev-libs/gmp:* )
+	lzma? ( app-arch/xz-utils )
+	openmp? ( sys-devel/gcc:=[openmp] )
+	$(python_gen_cond_dep '
+		doc? (
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		)
+	')"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+QA_EXECSTACK=usr/lib/gnatcoll_readline.*/libgnatcoll_readline.*
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ada_pkg_setup
+}
+
+src_prepare() {
+	rm -r python || die
+	mv python3 python || die
+	default
+}
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XLIBRARY_TYPE=$2 -P $1/gnatcoll_$1.gpr -XBUILD="PROD" \
+			-XGNATCOLL_VERSION=${PV} \
+			-XGNATCOLL_ICONV_OPT= -XGNATCOLL_PYTHON_CFLAGS="-I$(python_get_includedir)" \
+			-XGNATCOLL_PYTHON_LIBS=$(python_get_library_path) \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			build cpp $lib
+			build iconv $lib
+			use gmp && build gmp $lib
+			use lzma && build lzma $lib
+			use openmp && build omp $lib
+			build python $lib
+			build syslog $lib
+			build readline $lib
+			build zlib $lib
+		fi
+	done
+	if use doc; then
+		emake -C iconv/docs html
+		emake -C readline/docs html
+		emake -C syslog/docs html
+		mkdir html
+		mv iconv/docs/_build/html html/iconv || die
+		mv readline/docs/_build/html html/readline || die
+		mv syslog/docs/_build/html html/syslog || die
+	fi
+}
+
+src_install() {
+	build () {
+		gprinstall -p -f -XBUILD=PROD --prefix="${D}"/usr -XLIBRARY_TYPE=$2 \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XGNATCOLL_VERSION=${PV} --build-var=LIBRARY_TYPE \
+			-XGNATCOLL_ICONV_OPT= -P $1/gnatcoll_$1.gpr --build-name=$2
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			build cpp $lib
+			use gmp && build gmp $lib
+			build iconv $lib
+			use lzma && build lzma $lib
+			use openmp && build omp $lib
+			build python $lib
+			build syslog $lib
+			build readline $lib
+			use lzma && build lzma $lib
+			build zlib $lib
+		fi
+	done
+	rm -rf "${D}"/usr/share/gpr/manifests
+	use doc && HTML_DOCS=( html/* )
+	einstalldocs
+}