1 files changed, 49 insertions, 0 deletions
diff --git a/dev-ada/gnatmem/gnatmem-2020.ebuild b/dev-ada/gnatmem/gnatmem-2020.ebuild
new file mode 100644
index 000000000000..48f6cd713a4b
--- /dev/null
+++ b/dev-ada/gnatmem/gnatmem-2020.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ADA_COMPAT=( gnat_201{6,7,8,9} )
+inherit ada multiprocessing autotools
+
+MYP=${P}-20200429-19911-src
+
+DESCRIPTION="Monitors dynamic allocation and deallocation activity in a program"
+HOMEPAGE="http://libre.adacore.com/"
+SRC_URI="https://community.download.adacore.com/v1/77354fedca0441f882e17b6a73ac5631bff26237?filename=${MYP}.tar.gz
+	-> ${MYP}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="${ADA_DEPS}"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]
+	sys-libs/binutils-libs:="
+
+REQUIRED_USE="${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2018-gentoo.patch
+)
+
+src_prepare() {
+	default
+	mv configure.in configure.ac
+	eautoreconf
+}
+
+src_compile() {
+	gprbuild -v -Pgnatmem.gpr -j$(makeopts_jobs) \
+		-cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} \
+		-largs ${LDFLAGS} \
+		|| die
+}
+
+src_install() {
+	dobin obj/gnatmem
+}