1 files changed, 30 insertions, 18 deletions
diff --git a/app-text/ttf2pt1/ttf2pt1-3.4.4-r1.ebuild b/app-text/ttf2pt1/ttf2pt1-3.4.4-r1.ebuild
index ed543c6808a4..fcc8361c32a0 100644
--- a/app-text/ttf2pt1/ttf2pt1-3.4.4-r1.ebuild
+++ b/app-text/ttf2pt1/ttf2pt1-3.4.4-r1.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-inherit eutils multilib toolchain-funcs
+inherit toolchain-funcs
 
 DESCRIPTION="True Type Font to Postscript Type 1 Converter"
 HOMEPAGE="http://ttf2pt1.sourceforge.net/"
@@ -12,28 +12,40 @@ SRC_URI="mirror://sourceforge/ttf2pt1/${P}.tgz"
 LICENSE="ttf2pt1"
 SLOT="0"
 KEYWORDS="amd64 ppc sparc x86"
-IUSE=""
 
 DEPEND=">=media-libs/freetype-2.5.1:2"
 RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-Makefile.patch
+	"${FILESDIR}"/${P}-LDFLAGS.patch
+	"${FILESDIR}"/${PN}-3.4.0-man-pages.diff
+	"${FILESDIR}"/${P}-freetype.patch
+)
 
 src_prepare() {
-	epatch "${FILESDIR}"/${P}-Makefile.patch
-	epatch "${FILESDIR}"/${P}-LDFLAGS.patch
-	epatch "${FILESDIR}"/${PN}-3.4.0-man-pages.diff
-	epatch "${FILESDIR}"/${P}-freetype.patch
-
-	sed -i -e "/^CC=/ { s:gcc:$(tc-getCC): }" Makefile
-	sed -i -e "/^CFLAGS_SYS=/ { s:-O.*$:${CFLAGS}: }" Makefile
-	sed -i -e "/^LIBS_FT=/ { s:-L/usr/lib:-L/usr/$(get_libdir): }" Makefile
-	sed -i -e "/^LIBXDIR =/ { s:libexec:$(get_libdir): }" Makefile
+	default
+
+	sed -i \
+		-e "/^CC=/ { s:gcc:$(tc-getCC): }" \
+		-e "/^CFLAGS_SYS=/ { s:-O.*$:${CFLAGS}: }" \
+		-e "/^LIBS_FT=/ { s:-L/usr/lib:-L${ESYSROOT}/usr/$(get_libdir): }" \
+		-e "s:-I/usr/include/freetype2 -I/usr/include:$($(tc-getPKG_CONFIG) --cflags freetype2):" \
+		-e "s:-L/usr/lib -lfreetype:$($(tc-getPKG_CONFIG) --libs freetype2):" \
+		-e "/^LIBXDIR =/ { s:libexec:$(get_libdir): }" \
+		-e "/chown/d" \
+		-e "/chgrp/d" \
+		-e "/chmod/d" \
+		Makefile || die
 }
 
 src_install() {
-	emake INSTDIR="${D}"/usr install
+	emake INSTDIR="${ED}"/usr install
 	dodir /usr/share/doc/${PF}
-	pushd "${D}"/usr/share/ttf2pt1 > /dev/null
-	rm -r app other
-	mv [A-Z]* ../doc/${PF}
-	popd > /dev/null
+
+	pushd "${ED}"/usr/share/ttf2pt1 > /dev/null || die
+	rm -r app other || die
+	mv [A-Z]* ../doc/${PF} || die
+	popd > /dev/null || die
 }