1 files changed, 67 insertions, 0 deletions
diff --git a/app-text/libetonyek/libetonyek-0.1.6.ebuild b/app-text/libetonyek/libetonyek-0.1.6.ebuild
new file mode 100644
index 000000000000..e73685fed275
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+inherit autotools
+[[ ${PV} == 9999 ]] && inherit git-r3
+
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="amd64 ~arm ~arm64 x86"
+IUSE="doc static-libs test"
+
+RDEPEND="
+	>=app-text/liblangtag-0.5
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	>=dev-util/mdds-1.2.0:1
+	media-libs/glm
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-mdds-1.2.patch" # patch taken from Debian
+	"${FILESDIR}/${P}-drop-test.patch" # bug 595022
+)
+
+pkg_pretend() {
+	if [[ $(gcc-major-version) -lt 4 ]] || {
+		[[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -lt 8 ]]; }
+	then
+		eerror "Compilation with gcc older than 4.8 is not supported"
+		die "Too old gcc found."
+	fi
+}
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with doc docs) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}