1 files changed, 48 insertions, 0 deletions
diff --git a/app-text/enchant/enchant-2.1.1.ebuild b/app-text/enchant/enchant-2.1.1.ebuild
new file mode 100644
index 000000000000..4e9c52c25da6
--- /dev/null
+++ b/app-text/enchant/enchant-2.1.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Spellchecker wrapping library"
+HOMEPAGE="https://abiword.github.io/enchant/"
+SRC_URI="https://github.com/AbiWord/enchant/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+
+IUSE="aspell +hunspell static-libs test zemberek"
+REQUIRED_USE="|| ( hunspell aspell zemberek )"
+
+# FIXME: depends on unittest++ but through pkgconfig which is a Debian hack, bug #629742
+COMMON_DEPENDS="
+	>=dev-libs/glib-2.6:2
+	aspell? ( app-text/aspell )
+	hunspell? ( >=app-text/hunspell-1.2.1:0= )
+	zemberek? ( dev-libs/dbus-glib )
+"
+RDEPEND="${COMMON_DEPENDS}
+	zemberek? ( app-text/zemberek-server )
+"
+DEPEND="${COMMON_DEPENDS}
+	virtual/pkgconfig
+"
+#	test? ( dev-libs/unittest++ )
+
+RESTRICT="test"
+
+src_configure() {
+	econf \
+		$(use_with aspell) \
+		$(use_with hunspell) \
+		$(use_enable static-libs static) \
+		$(use_with zemberek) \
+		--without-hspell \
+		--without-voikko \
+		--with-hunspell-dir="${EPREFIX}"/usr/share/hunspell/
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}