3 files changed, 187 insertions, 3 deletions
diff --git a/app-misc/lirc/Manifest b/app-misc/lirc/Manifest
index 07fd35f0d7d0..66257660c18a 100644
--- a/app-misc/lirc/Manifest
+++ b/app-misc/lirc/Manifest
@@ -8,5 +8,7 @@ AUX lircmd-0.10.0.conf 57 BLAKE2B 8c39aac91bf5ac603a1495bb7e27b74ee5f09e55e35297
 AUX lircmd-0.9.4a-r2 382 BLAKE2B 14e6f7822d8878a9047fc26cb0927ae61c70092788133a387be62a9e54b3d4f3c78734f5dd0a54ddb04dd2b48ba270177ca7af777ac80ba8bacdcbe3f9ce2d62 SHA512 c744553b6246e62845ee61e18d78d97e7242969d0bb5478072bd9072ce0a02486306b577ca64c1c569c9b136e3231a4f0663c94114879827329a769e5f36413d
 AUX modprobed.lirc 549 BLAKE2B f58dcefff1becd48edaddab0d48e46f361b99de714bc8d3ae0d72f49fc8699fe9b9c7d8818a94eb7b40a5a653bfc8ca61ec11374c49ecebd1ef235d4ed8b8c08 SHA512 a64cac97e21ab53c247d8dd3e518b3caee5eeb9c3558727eba8a04684894c6be1695ce681e71d559474f4e78bbb39130d97f843eae18e56b3d3eb70f1fbefc63
 DIST lirc-0.10.1.tar.bz2 2523226 BLAKE2B 47b7ee87de8f64f7f829af519c0d296a85cf91790148927e850965177d4984bb994a0ad122cb59c3db508813d0824ffec45126e794abd08174a052361cea53e5 SHA512 31c0b6ee169b302b99994a2a3fa0ebcae0e01cb83c02fe02acf1de5ba8cf77a091a0221c7d8104448c30930adafe654cd08afb7d0df6b5b7ec2d47df26e5df9d
-EBUILD lirc-0.10.1-r4.ebuild 3880 BLAKE2B b253911013a334e7787e6f027911d89f71672d07e21cdb037c2833dc4b0104126a2a8ca2974ec9797d5ff817e9dd64bda5fa7d0ff7fd407ae48c0e09af3efca0 SHA512 9157023675df9a0c41a8540d267879ccd7ac06ffe3f97215f05c7c095f9c86376eb20c2e3b3b047a790e4516dd7654bdecae37dd9c75817325dfe8eaed7ef649
+DIST lirc_0.10.1-7.debian.tar.xz 39392 BLAKE2B cb7527bb33a1d724fea487ca468f98f406c8af894b185580dd285ed46ee0d7f6eeb5c2d66ae09c917d580485568f6510ef968283c56511dc9b4281c77fcc4563 SHA512 9bcd7dc2d30647ab807a65036c02d4adc425af288046d8f0b9bee2f38389f39be21103e4980684827e736b4b76a05688ae870f0871bc50213de429c35b70211e
+EBUILD lirc-0.10.1-r4.ebuild 3883 BLAKE2B 7e92b4db1b735321745a27cde5646d33f4f29e1aa383be5f2c0a9666f61af1152fe92652c0f0605ba6bc421bf912a99b76848669dd9f4f230deff93adf34ef6e SHA512 76d026e9c9b46fa502cc45b3d76cd9b830fdcd7cb56e7b207fa376a932cb6daad782bc1dc70a41b0f873dc1e82ff9796606d694e52821d317495cc046f63e765
+EBUILD lirc-0.10.1_p7.ebuild 4367 BLAKE2B 074285194814a7898a201194b0a3f7d90dc5efb0f2840ca00d5a692d3534f2ce6101e56d957cb9d79da26f69df5c408da6f5730b3f463009c2ecdeb69bb9c260 SHA512 083a027d7ccc0cc42d9a0fec5cf756898df2b76ef72c92bc4fb194a4b7fd1e042a1d3309ff221c104ee78d3da25f3f0dc2fb3e006daa52fd7407bf0a35c94bcc
 MISC metadata.xml 818 BLAKE2B 129ec702e5eb5421a4f8d0746b69b408d28475d6d8ba50ceadfee86efe759c01b74362fd15ffcdddfc94fb5977d5b2b41ac518a07c209f5a8b3034fcbadfca16 SHA512 4202d16440fa9ff030136c502bc998c8d9677e10451693bec5ad8e679ae82c3e3996aa957d0297edf6c636ff863c1f2dc0b7c4207212758a66f57dcc3d19b83b
diff --git a/app-misc/lirc/lirc-0.10.1-r4.ebuild b/app-misc/lirc/lirc-0.10.1-r4.ebuild
index 7e238eb7ffee..00b07b2c4453 100644
--- a/app-misc/lirc/lirc-0.10.1-r4.ebuild
+++ b/app-misc/lirc/lirc-0.10.1-r4.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{8,9} )
+PYTHON_COMPAT=( python3_{8,9,10} )
 
 inherit flag-o-matic linux-info python-single-r1 systemd xdg-utils
 
diff --git a/app-misc/lirc/lirc-0.10.1_p7.ebuild b/app-misc/lirc/lirc-0.10.1_p7.ebuild
new file mode 100644
index 000000000000..c01e42bc20ad
--- /dev/null
+++ b/app-misc/lirc/lirc-0.10.1_p7.ebuild
@@ -0,0 +1,182 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit linux-info python-single-r1 xdg-utils
+
+DESCRIPTION="decode and send infra-red signals of many commonly used remote controls"
+HOMEPAGE="https://www.lirc.org/"
+
+LIRC_DRIVER_DEVICE="/dev/lirc0"
+
+MY_P=${PN}-${PV/_/-}
+S="${WORKDIR}/${MY_P}"
+
+if [[ ${PV} == *_pre* ]] ; then
+	SRC_URI="https://www.lirc.org/software/snapshots/${MY_P}.tar.bz2"
+elif [[ ${PV} == *_p* ]] ; then
+	inherit autotools
+	SRC_URI="mirror://sourceforge/lirc/${PN}-$(ver_cut 1-3).tar.bz2"
+	SRC_URI+=" mirror://debian/pool/main/l/${PN}/${PN}_$(ver_cut 1-3)-$(ver_cut 5-).debian.tar.xz"
+	S="${WORKDIR}"/${PN}-$(ver_cut 1-3)
+else
+	SRC_URI="mirror://sourceforge/lirc/${MY_P}.tar.bz2"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc ppc64 ~riscv x86"
+IUSE="audio +devinput doc ftdi gtk inputlirc static-libs systemd +uinput usb X"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	gtk? ( X )
+"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	audio? (
+		>media-libs/portaudio-18
+		media-libs/alsa-lib
+	)
+	$(python_gen_cond_dep '
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	')
+	ftdi? ( dev-embedded/libftdi:0 )
+	systemd? ( sys-apps/systemd )
+	usb? ( virtual/libusb:0 )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	dev-libs/libxslt
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	')
+	doc? ( app-doc/doxygen )
+	sys-apps/kmod
+	sys-kernel/linux-headers
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	gtk? (
+		x11-libs/vte[introspection]
+		$(python_gen_cond_dep '
+			dev-python/pygobject[${PYTHON_USEDEP}]
+		')
+	)
+	inputlirc? ( app-misc/inputlircd )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.10.1-unsafe-load.patch"
+	"${FILESDIR}/${PN}-0.10.1-runtimedirectory.patch"
+)
+
+MAKEOPTS+=" -j1"
+
+pkg_setup() {
+	use uinput && CONFIG_CHECK="~INPUT_UINPUT"
+	python-single-r1_pkg_setup
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Keep eautoreconf until a new release to fix Python macros
+	# bug #849788
+	if [[ -d "${WORKDIR}"/debian/patches ]] ; then
+		eapply $(sed -e 's:^:../debian/patches/:' ../debian/patches/series || die)
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	econf \
+		--localstatedir="${EPREFIX}/var" \
+		$(use_enable static-libs static) \
+		$(use_enable devinput) \
+		$(use_enable uinput) \
+		$(use_with X x)
+}
+
+src_install() {
+	default
+
+	if use !gtk ; then
+		# lirc-setup requires gtk
+		rm "${ED}"/usr/bin/lirc-setup || die
+	fi
+
+	newinitd "${FILESDIR}"/lircd-0.8.6-r2 lircd
+	newinitd "${FILESDIR}"/lircmd-0.9.4a-r2 lircmd
+	newconfd "${FILESDIR}"/lircd.conf.4 lircd
+	newconfd "${FILESDIR}"/lircmd-0.10.0.conf lircmd
+
+	insinto /etc/modprobe.d/
+	newins "${FILESDIR}"/modprobed.lirc lirc.conf
+
+	newinitd "${FILESDIR}"/irexec-initd-0.9.4a-r2 irexec
+	newconfd "${FILESDIR}"/irexec-confd irexec
+
+	keepdir /etc/lirc
+	if [[ -e "${ED}"/etc/lirc/lircd.conf ]]; then
+		newdoc "${ED}"/etc/lirc/lircd.conf lircd.conf.example
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+
+	# Avoid QA notice
+	rm -d "${ED}"/var/run/lirc || die
+	rm -d "${ED}"/var/run || die
+}
+
+pkg_preinst() {
+	local dir="${EROOT}/etc/modprobe.d"
+	if [[ -a "${dir}"/lirc && ! -a "${dir}"/lirc.conf ]]; then
+		elog "Renaming ${dir}/lirc to lirc.conf"
+		mv -f "${dir}/lirc" "${dir}/lirc.conf" || die
+	fi
+
+	# copy the first file that can be found
+	if [[ -f "${EROOT}"/etc/lirc/lircd.conf ]]; then
+		cp "${EROOT}"/etc/lirc/lircd.conf "${T}"/lircd.conf || die
+	elif [[ -f "${EROOT}"/etc/lircd.conf ]]; then
+		cp "${EROOT}"/etc/lircd.conf "${T}"/lircd.conf || die
+		MOVE_OLD_LIRCD_CONF=1
+	elif [[ -f "${ED}"/etc/lirc/lircd.conf ]]; then
+		cp "${ED}"/etc/lirc/lircd.conf "${T}"/lircd.conf || die
+	fi
+
+	# stop portage from touching the config file
+	if [[ -e "${ED}"/etc/lirc/lircd.conf ]]; then
+		rm -f "${ED}"/etc/lirc/lircd.conf || die
+	fi
+}
+
+pkg_postinst() {
+	# copy config file to new location
+	# without portage knowing about it
+	# so it will not delete it on unmerge or ever touch it again
+	if [[ -e "${T}"/lircd.conf ]]; then
+		cp "${T}"/lircd.conf "${EROOT}"/etc/lirc/lircd.conf || die
+		if [[ "$MOVE_OLD_LIRCD_CONF" = "1" ]]; then
+			elog "Moved /etc/lircd.conf to /etc/lirc/lircd.conf"
+			rm -f "${EROOT}"/etc/lircd.conf || die
+		fi
+	fi
+
+	einfo "The new default location for lircd.conf is inside of"
+	einfo "${EROOT}/etc/lirc/ directory"
+}