3 files changed, 81 insertions, 0 deletions
diff --git a/app-misc/gentoo/Manifest b/app-misc/gentoo/Manifest
new file mode 100644
index 000000000000..87e45180a8c2
--- /dev/null
+++ b/app-misc/gentoo/Manifest
@@ -0,0 +1,3 @@
+DIST gentoo-0.20.7.tar.gz 1414198 BLAKE2B 18af2f136557d5d5674e05669839e1213c1c8234bfb2a14875057989040cae2955e7a569456a93fb181121afa796e711a8b26e26397d743dc6d3ac2eefd7088d SHA512 7a4d601526d7071392bc3f2f34fd86337f4186fc45e633ed359b32ba44f43faddc4760a9ebd2e20d08662755052dd4c02a06724d274f98db342ac53fa28e39b0
+EBUILD gentoo-0.20.7.ebuild 1281 BLAKE2B 2276e3e4126dfd2014720a4e1507927914b7a6f4e484bbdce504ee6e3807958027c5aef9dc491870b45f8c83e12c8812cb3c9d0542d824022104b1ca1ef6bff1 SHA512 1c8844d88850a7a47e080b64fd58de787396500dd5549d67c383dc1a29d15f553e06bf37eab56ba9323459e01e10cbedd2f5c2137185833a3617a337d538d8b7
+MISC metadata.xml 352 BLAKE2B 72fa87ea40fa0242a63fb53b736533de198a19cbdbdd751ee68413ff914b064169cdf5df0b5abed6d3d757a8a044c40261abd25bbbfe90ee159264a703fa977b SHA512 ff05feda3a7284c70f12d7fe7f7beca8c49eeb120c6c7302c73f5c28f2f903ecb97cf91a8a374e7b0c86d9dfba1c80627274a30249a388a65390303dd09d194a
diff --git a/app-misc/gentoo/gentoo-0.20.7.ebuild b/app-misc/gentoo/gentoo-0.20.7.ebuild
new file mode 100644
index 000000000000..f84fcd4a62e7
--- /dev/null
+++ b/app-misc/gentoo/gentoo-0.20.7.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils
+
+DESCRIPTION="Graphical file manager for Unix-like systems, using GTK+"
+HOMEPAGE="http://gentoo.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 sparc x86"
+IUSE="nls"
+
+RDEPEND="
+	>x11-libs/gtk+-3.12:3
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/pango
+"
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+
+DOCS=(
+	AUTHORS BUGS CONFIG-CHANGES CREDITS NEWS README TODO docs/{FAQ,menus.txt}
+)
+
+src_prepare() {
+	sed -i \
+		-e 's^icons/gnome/16x16/mimetypes^gentoo/icons^' \
+		gentoorc.in || die
+	sed -i \
+		-e '/GTK_DISABLE_DEPRECATED/d' \
+		-e '/^GENTOO_CFLAGS=/s|".*"|"${CFLAGS}"|g' \
+		-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
+		configure.ac || die #357343
+
+	eapply_user
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/gentoo \
+		$(use_enable nls)
+}
+
+src_install() {
+	default
+
+	docinto html
+	dodoc -r docs/{images,config,*.{html,css}}
+
+	newman docs/gentoo.1x gentoo.1
+
+	docinto scratch
+	dodoc docs/scratch/*
+
+	make_desktop_entry ${PN} Gentoo \
+		/usr/share/${PN}/icons/${PN}.png \
+		"System;FileTools;FileManager"
+}
diff --git a/app-misc/gentoo/metadata.xml b/app-misc/gentoo/metadata.xml
new file mode 100644
index 000000000000..663d8782116a
--- /dev/null
+++ b/app-misc/gentoo/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>desktop-misc@gentoo.org</email>
+		<name>Gentoo Desktop Miscellaneous Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">gentoo</remote-id>
+	</upstream>
+</pkgmetadata>