3 files changed, 332 insertions, 2 deletions
diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index c50cd5e0d52d..5b1948f5e559 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -22,10 +22,13 @@ DIST libvirt-7.3.0.tar.xz 8680468 BLAKE2B 88ad3dbac627203419eb80b28649613480a287
 DIST libvirt-7.3.0.tar.xz.asc 833 BLAKE2B 812a7cf4bcaef88a4229008579a18da19d78b0a988890359907e4067b5eb6d74176907875a3a27775ffabaf29fb4d0e92c7f2ec13042ef8657c09ad6b287984d SHA512 f5349bb6c7919b54518a2ffc058592fb588045d37d18dfce5efb7e2f512c2a19b0f956d6ee34a16982cdaec4c23954300f7e130656afeb3cf535c65a0d62c04e
 DIST libvirt-7.4.0.tar.xz 8617788 BLAKE2B 06271895ac39865df632b6ad669eb20d1f1bb774b4a854ee2461174ac5ccf688b0f8ecffc2d9d0b12491e0e948beb377d52efdf40a2729d14b4b3d9bc8835cc2 SHA512 efe3fb2813613c3c5e94ed49d0cae4ad92cca6a727a8b55808d8c3bdfacb355642796dfab49362ee59654f9471f9134b96374ced50cc9b3227f4f1c6201bf7f1
 DIST libvirt-7.4.0.tar.xz.asc 833 BLAKE2B c9d63bb9cdd604663754ccd927a5a1305131617b1d4edb51d289878ff67b7168e882ec1bf0f16aaea509aa32b8419a3c6420615051bd8f42216ce9d1aeae601b SHA512 9a887cf73fb494e55617a69863a0877fba56d180fecbec892a7990f76bc6e1fe15871b4e688e88289eb7acf3ab4a70c1d6202b224cf3c9a96ecb1ecfb2279b2c
+DIST libvirt-7.5.0.tar.xz 8642788 BLAKE2B 467dbd2a337beee5d9f10de7bc37ca988e85fad17fb75e6ab73c13cf79eceab27c9ff51bbe2ac9f6c121feed4c67860fa263e601e10f6b1dd7b8a647b53228a7 SHA512 cf89800c8970b8b1373ee32cc49ea88b87e76b50fd134df5da354be83e0ef490e514f16425c1c16eb3989fbadd3ba7d9976972fbbae6cb40db3d2ae94863219d
+DIST libvirt-7.5.0.tar.xz.asc 833 BLAKE2B ab9ba2a02e4af90002fffbcd0bc04f9faa1d5a23ab815d6b9b6ef1410d9d114fc07c1b29850b59d1ab4ea3a186f4b7d65f5a5ca37d65f3034146617445849dcb SHA512 ebcc1fcce10e19e0a4ae43fbf9bfd5b1b7732829eeb3543c84ba24e0a5d9872be692e7b6c105cdcd730d1c26b895b306387ab380623acf6bba242bd2c62ec7b2
 EBUILD libvirt-7.0.0-r3.ebuild 8786 BLAKE2B 6238ffc390bcaa58d3f22096c3fa774f1d584e888d5803f219a3fde22337119a8b66a72266405ec1c902fb083324da66492083ce8813d6089b913d97bc413153 SHA512 362878616424eb2416e3ce53d379864198bfddf47ef552c4451350a1eb1c52274ea8d158609a387d4d452d82097ef85d908962ebcfe5c29d31363ae3e77232d4
 EBUILD libvirt-7.1.0-r1.ebuild 8479 BLAKE2B 2b16121f4b0930eae86e7866ca7ad5859cc5009cca4d3b2d3e08566a40dbe94f54e324435fdaa8ac8c6b8eff269fc02421c503b52ffd7e5ab31577bc40b03873 SHA512 75a840582349c8c9373e6f15645818a0f5ba6c8aa4510ab62a16499c9dc7d06f23d1caf488ada35d6d51b24fb62cb96d9c362c0cef592b75adaee8516739c4c9
 EBUILD libvirt-7.2.0-r1.ebuild 8285 BLAKE2B 7d5c0c746e44714177a6192250992e190d57deb8ee342e7fe5f457b2bb6a905bff860544f7fd6267624d46b95b0e75caf905dc6c29ea273f8c72cb5edbaadd45 SHA512 a578a69498e3bbe5b5d9df0509c9cfc6294d49f351bdf4ab20df8392152d655777897c8d15e58c2ff344251c444b981f3f7e58c49b09d952816733dd73f0ab9d
 EBUILD libvirt-7.3.0.ebuild 8181 BLAKE2B 567f3971d685fb3a6a782b900e71bd176ccd4f14b4f62b3d713b3c17c5a1afcc9edd853b6d97cb4b5fa940ef9f1cd266b709c4b08ee87a9faf28f6548397c8ad SHA512 40d1484626c17acee923456ae6295a90a113b8d6810a4ca0c7a90e54fc87df3078190e4315b41f3f1a82af0acfe4c0222f5fd718215aabe22cf18b16b170ae1d
 EBUILD libvirt-7.4.0.ebuild 8205 BLAKE2B 3174d1cff6880724f68be9950b834931409a2f47860ecdc33bdf71d6eb1f5ab73112d37566b2b16e3d5321047998dd17a858e3901b1c4550855057631dc408c9 SHA512 582e804a9599f15666a1633709ddacece08238214f8a18c1372efa0ce3b67f5bbb3a492a5e334cbd2009a562c9d402d0afff5a366e981404fd95bc4a3f6c9dae
-EBUILD libvirt-9999.ebuild 8209 BLAKE2B 75eae972c65414567b4642006d3f8808a3891869b2f20b35b83e4915e3fe8fc260faed427ebec4a576b02f27db548b34b000a409fc41f565abc69def47611fdb SHA512 36087e78dcaa57efe1d479cc76323d6bc3634a72b2e2cf16a4f981f3cc5caca9f1854fad0d20f3745e836a4f86968659434237492f83779151405337a45dcf9b
+EBUILD libvirt-7.5.0.ebuild 8209 BLAKE2B 110567e3a8c637fae3d590e9c10b4de7ae5f0e0c3742fb812fea64df9e5401a66c34cd3a312dfa2eb05636950cd54021c402b40ee643ed47920d9dcd01539ba1 SHA512 1e88f9c6779d494bcf33ee2ccf245fb1c2d45fb53e421d88c13edaef9fff69f1b5f20c8622d08af241ca717291c42a36f5eb2f70822f69bd68b40ba492a008a3
+EBUILD libvirt-9999.ebuild 8209 BLAKE2B 110567e3a8c637fae3d590e9c10b4de7ae5f0e0c3742fb812fea64df9e5401a66c34cd3a312dfa2eb05636950cd54021c402b40ee643ed47920d9dcd01539ba1 SHA512 1e88f9c6779d494bcf33ee2ccf245fb1c2d45fb53e421d88c13edaef9fff69f1b5f20c8622d08af241ca717291c42a36f5eb2f70822f69bd68b40ba492a008a3
 MISC metadata.xml 3326 BLAKE2B 70997d3eee5387a0735faad11a891927ad7c96b5fed632c3774611a7c35159eacfd6b0e9561c09dd08d64112c6bd66ff011fd58ed23520bc4f4f531c0d5f4693 SHA512 651bf4d8eec1af7b08c8b1050f2a4d57fa8e205205c59f231d3f84be643a71633b1426e9df1c83c838636245503bfefeef66696ddb9dc9e8da6b1aadee741856
diff --git a/app-emulation/libvirt/libvirt-7.5.0.ebuild b/app-emulation/libvirt/libvirt-7.5.0.ebuild
new file mode 100644
index 000000000000..2abe4227b78a
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-7.5.0.ebuild
@@ -0,0 +1,327 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit meson bash-completion-r1 linux-info python-any-r1 readme.gentoo-r1 tmpfiles verify-sig
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt.git"
+	EGIT_BRANCH="master"
+	SRC_URI=""
+	SLOT="0"
+else
+	SRC_URI="https://libvirt.org/sources/${P}.tar.xz
+		verify-sig? ( https://libvirt.org/sources/${P}.tar.xz.asc )"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+	SLOT="0/${PV}"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="https://www.libvirt.org/ https://gitlab.com/libvirt/libvirt/"
+LICENSE="LGPL-2.1"
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/libvirt.org.asc
+IUSE="
+	apparmor audit bash-completion +caps dtrace firewalld fuse glusterfs
+	iscsi iscsi-direct +libvirtd lvm libssh lxc nfs nls numa openvz
+	parted pcap policykit +qemu rbd sasl selinux +udev
+	virtualbox +virt-network wireshark-plugins xen zfs
+"
+
+REQUIRED_USE="
+	firewalld? ( virt-network )
+	libvirtd? ( || ( lxc openvz qemu virtualbox xen ) )
+	lxc? ( caps libvirtd )
+	openvz? ( libvirtd )
+	qemu? ( libvirtd )
+	virt-network? ( libvirtd )
+	virtualbox? ( libvirtd )
+	xen? ( libvirtd )"
+
+BDEPEND="
+	app-text/xhtml1
+	dev-lang/perl
+	dev-libs/libxslt
+	dev-perl/XML-XPath
+	dev-python/docutils
+	virtual/pkgconfig
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	verify-sig? ( app-crypt/openpgp-keys-libvirt )"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent
+RDEPEND="
+	acct-user/qemu
+	app-misc/scrub
+	>=dev-libs/glib-2.48.0
+	dev-libs/libgcrypt:0
+	dev-libs/libnl:3
+	>=dev-libs/libxml2-2.7.6
+	>=net-analyzer/openbsd-netcat-1.105-r1
+	>=net-libs/gnutls-1.0.25:0=
+	net-libs/libssh2
+	net-libs/libtirpc
+	net-libs/rpcsvc-proto
+	>=net-misc/curl-7.18.0
+	sys-apps/dbus
+	sys-apps/dmidecode
+	sys-devel/gettext
+	sys-libs/ncurses:0=
+	sys-libs/readline:=
+	virtual/acl
+	apparmor? ( sys-libs/libapparmor )
+	audit? ( sys-process/audit )
+	caps? ( sys-libs/libcap-ng )
+	dtrace? ( dev-util/systemtap )
+	firewalld? ( >=net-firewall/firewalld-0.6.3 )
+	fuse? ( sys-fs/fuse:0= )
+	glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+	iscsi? ( sys-block/open-iscsi )
+	iscsi-direct? ( >=net-libs/libiscsi-1.18.0 )
+	libssh? ( net-libs/libssh )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2[-device-mapper-only(-)] )
+	lxc? ( !sys-apps/systemd[cgroup-hybrid(-)] )
+	nfs? ( net-fs/nfs-utils )
+	numa? (
+		>sys-process/numactl-2.0.2
+		sys-process/numad
+	)
+	parted? (
+		>=sys-block/parted-1.8[device-mapper]
+		sys-fs/lvm2[-device-mapper-only(-)]
+	)
+	pcap? ( >=net-libs/libpcap-1.0.0 )
+	policykit? (
+		acct-group/libvirt
+		>=sys-auth/polkit-0.9
+	)
+	qemu? (
+		>=app-emulation/qemu-2.11
+		dev-libs/yajl
+	)
+	rbd? ( sys-cluster/ceph )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	virt-network? (
+		net-dns/dnsmasq[dhcp,ipv6,script]
+		net-firewall/ebtables
+		>=net-firewall/iptables-1.4.10[ipv6]
+		net-misc/radvd
+		sys-apps/iproute2[-minimal]
+	)
+	wireshark-plugins? ( net-analyzer/wireshark:= )
+	xen? (
+		>=app-emulation/xen-4.9.0
+		app-emulation/xen-tools:=
+	)
+	udev? (
+		virtual/libudev
+		>=x11-libs/libpciaccess-0.10.9
+	)
+	zfs? ( sys-fs/zfs )"
+
+DEPEND="${BDEPEND}
+	${RDEPEND}
+	${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.0.0-fix_paths_in_libvirt-guests_sh.patch
+	"${FILESDIR}"/${PN}-6.7.0-do-not-use-sysconfig.patch
+	"${FILESDIR}"/${PN}-6.7.0-fix-paths-for-apparmor.patch
+)
+
+pkg_setup() {
+	# Check kernel configuration:
+	CONFIG_CHECK=""
+	use fuse && CONFIG_CHECK+="
+		~FUSE_FS"
+
+	use lvm && CONFIG_CHECK+="
+		~BLK_DEV_DM
+		~DM_MULTIPATH
+		~DM_SNAPSHOT"
+
+	use lxc && CONFIG_CHECK+="
+		~BLK_CGROUP
+		~CGROUP_CPUACCT
+		~CGROUP_DEVICE
+		~CGROUP_FREEZER
+		~CGROUP_NET_PRIO
+		~CGROUP_PERF
+		~CGROUPS
+		~CGROUP_SCHED
+		~CPUSETS
+		~IPC_NS
+		~MACVLAN
+		~NAMESPACES
+		~NET_CLS_CGROUP
+		~NET_NS
+		~PID_NS
+		~POSIX_MQUEUE
+		~SECURITYFS
+		~USER_NS
+		~UTS_NS
+		~VETH
+		~!GRKERNSEC_CHROOT_MOUNT
+		~!GRKERNSEC_CHROOT_DOUBLE
+		~!GRKERNSEC_CHROOT_PIVOT
+		~!GRKERNSEC_CHROOT_CHMOD
+		~!GRKERNSEC_CHROOT_CAPS"
+
+	kernel_is lt 4 7 && use lxc && CONFIG_CHECK+="
+		~DEVPTS_MULTIPLE_INSTANCES"
+
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_MARK_T
+		~BRIDGE_NF_EBTABLES
+		~NETFILTER_ADVANCED
+		~NETFILTER_XT_CONNMARK
+		~NETFILTER_XT_MARK
+		~NETFILTER_XT_TARGET_CHECKSUM
+		~IP_NF_FILTER
+		~IP_NF_MANGLE
+		~IP_NF_NAT
+		~IP_NF_TARGET_MASQUERADE
+		~IP6_NF_FILTER
+		~IP6_NF_MANGLE
+		~IP6_NF_NAT"
+	# Bandwidth Limiting Support
+	use virt-network && CONFIG_CHECK+="
+		~BRIDGE_EBT_T_NAT
+		~IP_NF_TARGET_REJECT
+		~NET_ACT_POLICE
+		~NET_CLS_FW
+		~NET_CLS_U32
+		~NET_SCH_HTB
+		~NET_SCH_INGRESS
+		~NET_SCH_SFQ"
+
+	ERROR_USER_NS="Optional depending on LXC configuration."
+
+	if [[ -n ${CONFIG_CHECK} ]]; then
+		linux-info_pkg_setup
+	fi
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	touch "${S}/.mailmap" || die
+
+	default
+	python_fix_shebang .
+
+	# Tweak the init script:
+	cp "${FILESDIR}/libvirtd.init-r19" "${S}/libvirtd.init" || die
+	sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+		-i "${S}/libvirtd.init" || die "sed failed"
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature apparmor)
+		$(meson_feature apparmor apparmor_profiles)
+		$(meson_feature audit)
+		$(meson_feature caps capng)
+		$(meson_feature dtrace)
+		$(meson_feature firewalld)
+		$(meson_feature fuse)
+		$(meson_feature glusterfs)
+		$(meson_feature glusterfs storage_gluster)
+		$(meson_feature iscsi storage_iscsi)
+		$(meson_feature iscsi-direct storage_iscsi_direct)
+		$(meson_feature libvirtd driver_libvirtd)
+		$(meson_feature libssh)
+		$(meson_feature lvm storage_lvm)
+		$(meson_feature lvm storage_mpath)
+		$(meson_feature lxc driver_lxc)
+		$(meson_feature nls)
+		$(meson_feature numa numactl)
+		$(meson_feature numa numad)
+		$(meson_feature openvz driver_openvz)
+		$(meson_feature parted storage_disk)
+		$(meson_feature pcap libpcap)
+		$(meson_feature policykit polkit)
+		$(meson_feature qemu driver_qemu)
+		$(meson_feature qemu yajl)
+		$(meson_feature rbd storage_rbd)
+		$(meson_feature sasl)
+		$(meson_feature selinux)
+		$(meson_feature udev)
+		$(meson_feature virt-network driver_network)
+		$(meson_feature virtualbox driver_vbox)
+		$(meson_feature wireshark-plugins wireshark_dissector)
+		$(meson_feature xen driver_libxl)
+		$(meson_feature zfs storage_zfs)
+
+		-Dnetcf=disabled
+		-Dsanlock=disabled
+
+		-Ddriver_esx=enabled
+		-Dinit_script=systemd
+		-Dqemu_user=$(usex caps qemu root)
+		-Dqemu_group=$(usex caps qemu root)
+		-Ddriver_remote=enabled
+		-Dstorage_fs=enabled
+		-Ddriver_vmware=enabled
+
+		--localstatedir="${EPREFIX}/var"
+		-Drunstatedir="${EPREFIX}/run"
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	export VIR_TEST_DEBUG=1
+	meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	# Depending on configuration option, libvirt will create some bogus
+	# directoreis. They are either not used, or libvirtd is able to create
+	# them on demand, so let's remove them.
+	#
+	# Note, we are using -f here so that rm does not fail or warn if the
+	# directory is nonexistent.
+	rm -rf "${D}"/etc/sysconfig
+	rm -rf "${D}"/var
+	rm -rf "${D}"/run
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	newtmpfiles "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+	newinitd "${S}/libvirtd.init" libvirtd
+	newinitd "${FILESDIR}/libvirt-guests.init-r4" libvirt-guests
+	newinitd "${FILESDIR}/virtlockd.init-r2" virtlockd
+	newinitd "${FILESDIR}/virtlogd.init-r2" virtlogd
+
+	newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd
+	newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests
+
+	DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r3")
+	DISABLE_AUTOFORMATTING=true
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml || die
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	readme.gentoo_print_elog
+}
diff --git a/app-emulation/libvirt/libvirt-9999.ebuild b/app-emulation/libvirt/libvirt-9999.ebuild
index ccc4f6f1ce73..2abe4227b78a 100644
--- a/app-emulation/libvirt/libvirt-9999.ebuild
+++ b/app-emulation/libvirt/libvirt-9999.ebuild
@@ -117,7 +117,7 @@ RDEPEND="
 	)
 	wireshark-plugins? ( net-analyzer/wireshark:= )
 	xen? (
-		>=app-emulation/xen-4.6.0
+		>=app-emulation/xen-4.9.0
 		app-emulation/xen-tools:=
 	)
 	udev? (