1 files changed, 51 insertions, 0 deletions
diff --git a/app-emulation/containerd/containerd-1.0.0_beta2_p20171019.ebuild b/app-emulation/containerd/containerd-1.0.0_beta2_p20171019.ebuild
new file mode 100644
index 000000000000..559f2b19db5e
--- /dev/null
+++ b/app-emulation/containerd/containerd-1.0.0_beta2_p20171019.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/containerd/${PN}"
+
+inherit toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-vcs
+else
+	EGIT_COMMIT="992280e8e265f491f7a624ab82f3e238be086e49"
+	CONTAINERD_COMMIT="992280"
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="A daemon to control runC"
+HOMEPAGE="https://containerd.tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="hardened +seccomp"
+
+DEPEND="sys-fs/btrfs-progs"
+RDEPEND="|| ( >=app-emulation/docker-runc-1.0.0_rc4
+	>=app-emulation/runc-1.0.0_rc4 )
+	seccomp? ( sys-libs/libseccomp )"
+
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+src_prepare() {
+	default
+	if [[ ${PV} != *9999* ]]; then
+		sed -i -e "s/git describe --match.*$/echo ${PV})/"\
+			-e "s/git rev-parse HEAD.*$/echo $CONTAINERD_COMMIT)/"\
+			-e "s/-s -w//" \
+			Makefile || die
+	fi
+}
+
+src_compile() {
+	local options=( $(usex seccomp "seccomp" "") )
+	export GOPATH="${WORKDIR}/${P}" # ${PWD}/vendor
+	LDFLAGS=$(usex hardened '-extldflags -fno-PIC' '') emake BUILDTAGS="${options[@]}"
+}
+
+src_install() {
+	dobin bin/containerd{-shim,-stress,} bin/ctr
+}