1 files changed, 50 insertions, 0 deletions
diff --git a/app-emulation/buildah/buildah-1.13.1.ebuild b/app-emulation/buildah/buildah-1.13.1.ebuild
new file mode 100644
index 000000000000..9880537f2941
--- /dev/null
+++ b/app-emulation/buildah/buildah-1.13.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit bash-completion-r1 go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="A tool that facilitates building OCI images"
+HOMEPAGE="https://github.com/containers/buildah"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT MPL-2.0"
+SLOT="0"
+IUSE="selinux"
+EGIT_COMMIT="v${PV}"
+GIT_COMMIT="836d6d2"
+SRC_URI="https://github.com/containers/buildah/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+RDEPEND="app-crypt/gpgme:=
+	app-emulation/skopeo
+	dev-libs/libgpg-error:=
+	dev-libs/libassuan:=
+	sys-fs/lvm2:=
+	sys-libs/libseccomp:=
+	selinux? ( sys-libs/libselinux:= )"
+DEPEND="${RDEPEND}"
+RESTRICT="test"
+
+src_prepare() {
+	default
+	sed -e 's|^\(GIT_COMMIT ?= \).*|\1'${GIT_COMMIT}'|' -i Makefile || die
+
+	[[ -f selinux_tag.sh ]] || die
+	use selinux || { echo -e "#!/bin/sh\ntrue" > \
+		selinux_tag.sh || die; }
+}
+
+src_compile() {
+	export -n GOCACHE XDG_CACHE_HOME
+	emake all
+}
+
+src_install() {
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md install.md troubleshooting.md
+	doman docs/*.1
+	dodoc -r docs/tutorials
+	dobin ${PN} imgtype
+	dobashcomp contrib/completions/bash/buildah
+}
+
+src_test() {
+	emake test-unit
+}