1 files changed, 38 insertions, 0 deletions
diff --git a/app-crypt/jitterentropy/jitterentropy-3.0.1.ebuild b/app-crypt/jitterentropy/jitterentropy-3.0.1.ebuild
new file mode 100644
index 000000000000..921bb7705ddf
--- /dev/null
+++ b/app-crypt/jitterentropy/jitterentropy-3.0.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Hardware RNG based on CPU timing jitter"
+HOMEPAGE="https://github.com/smuellerDD/jitterentropy-library"
+SRC_URI="https://github.com/smuellerDD/jitterentropy-library/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~x86"
+IUSE="static-libs"
+
+S="${WORKDIR}/${PN}-library-${PV}"
+
+src_prepare() {
+	default
+
+	# Disable man page compression on install
+	sed -e '/\tgzip.*man/ d' -i Makefile || die
+	# Remove the default upstream optimization level
+	sed -e '/^CFLAGS +=/ s|-O2||' -i Makefile || die
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake PREFIX="${EPREFIX}/usr" \
+		  LIBDIR="$(get_libdir)" \
+		  DESTDIR="${D}" \
+		  INSTALL_STRIP="install" \
+		  install $(usex static-libs install-static '')
+}