1 files changed, 59 insertions, 0 deletions
diff --git a/app-admin/clustershell/clustershell-1.9-r1.ebuild b/app-admin/clustershell/clustershell-1.9-r1.ebuild
new file mode 100644
index 000000000000..3db2252a56af
--- /dev/null
+++ b/app-admin/clustershell/clustershell-1.9-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python framework for efficient cluster administration"
+HOMEPAGE="https://github.com/cea-hpc/clustershell/"
+SRC_URI="
+	https://github.com/cea-hpc/clustershell/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 ~x86"
+
+BDEPEND="
+	test? (
+		app-shells/pdsh
+		virtual/openssh
+		sys-devel/bc
+	)
+"
+
+RDEPEND="dev-python/pyyaml[${PYTHON_USEDEP}]"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	default
+
+	# remove test sets that require working ssh connection
+	rm tests/{CLIClush,TaskDistant*}Test.py || die
+}
+
+python_test() {
+	cd tests || die
+	# Automatic discovery does not work
+	"${EPYTHON}" -m unittest_or_fail -v *.py || die "Tests failed with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman doc/man/man*/*
+
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	einfo "Some default system-wide config files have been installed into"
+	einfo "/etc/${PN}"
+}