reinit the tree, so we can have metadata

4 files changed, 164 insertions, 0 deletions

diff --git a/xfce-base/thunar/Manifest b/xfce-base/thunar/Manifest
new file mode 100644
index 000000000000..24567b09eeb1
--- /dev/null
+++ b/xfce-base/thunar/Manifest
@@ -0,0 +1,7 @@
+DIST Thunar-1.6.10.tar.bz2 1948762 SHA256 7e9d24067268900e5e44d3325e60a1a2b2f8f556ec238ec12574fbea15fdee8a SHA512 56f9407907c85a631b390b6bf363ee863b5a126afc32e1b10e34434b997e82b86223737a0b0a1a8faf801258ad1cfa0585c9c3537c167f6968a2c4dac458395a WHIRLPOOL 813e3a1628227fbe27d221739e4946aa38b147ff4b165ff915b6a57b38ae544f54dc8facf19af0519fac5e903924459a34b6372c42985ed00e997e02434f4b71
+DIST Thunar-1.6.12.tar.bz2 1929112 SHA256 fb22091f07ec6de2c9d9d89c61289d2bc3436b36c8c53ccbc9c32ca8a99f2086 SHA512 d18e0fb6b58a65889dc47852a4c513acb7ff9a99fd70d34cbc6b2806d7818893b3c999c0a63f1b7af599d3ff4336b9637944989b97e5cc7431761ce493d2259d WHIRLPOOL 7a07f2453ab73af082c2d9ec9c54551c1bd63241b781695554a0526c4bca97129acb9068990ce65959c6fe39d1dd7d21fc9156405a5c8c87bc95e2f19faffbcc
+EBUILD thunar-1.6.10-r1.ebuild 1817 SHA256 2b9a180f9f241f0943cd63277993a4c3af5237f71c753106395dbf4958e9dc6d SHA512 d888e8e5e7d00291d085b4dd1cbdfe96b55b5d26c3b6252d450b0d31729b0a21e5a251de49507416d4592e9913c7861d568398fb946c9e3613844a7f3ea88cea WHIRLPOOL e84cc37cb62d3ecbc89557d1e76cbfb177fbc97b482e946c542b496f470e8db07bcf6af5f22b0177d7a08011a8a92e58b52c6e8b60b44c6d7d47a6f22c770369
+EBUILD thunar-1.6.12.ebuild 1966 SHA256 2a503c7c9542913f9412c11ee28c74b485ceac62667a585c1fb710c6097a46d0 SHA512 125a4ab415a28e42e6bb1b8aaea557f3c5a040a3433458ac2c00721a2c7305dc23f4ce7340c3802bfc3f120d0ac601b0eb1208dc96eea15d50b846b7919b2cf2 WHIRLPOOL 236d732e2f52754b0d983b8a3488df77d30ea228bdc5f72338f739be00815d59bab4ba6eba1f9f74c9ef09cde44b99715ffe8f22150cc7537591d6e5b365e36b
+MISC ChangeLog 2866 SHA256 cf64430cef536d724fc00605e8571207b34038c7da5c1d798c15283dc12d72ca SHA512 51bc40e8ff6491ed18f1693f812a03f5c2333eabb01d296223bcab4444324b8fb96e5e1d6879ad9d6711ebd0bf5f450d5736fa38ff77915f7e21a8dec13bc0bf WHIRLPOOL f6924215f361bbdf4de0770a63a7a45b7e49ffc1f13585bd6de01f96cd6e42a0abba253276e44d8d073229ca03c2b3f45462a1a5519b618bfd8c945e978dab61
+MISC ChangeLog-2015 24121 SHA256 1c4f24c98b48e24636c014feff70e2f437c4ca31e37a439e74512896a912dffc SHA512 867fe3a8b9f497484ce4965059cf0cc497c9826778a50db362cf2bb83e3c47681982c3feecce2a627d9c20f70770228e638ee11c75bf781f996bd79d32d83922 WHIRLPOOL 9c0d83039bc59dc9bce8b20a9dd3175569bfb1c45d938097d4a5b4fe58ccbdade0956ba904ee181b99b292e07f1e60dbcefb22bf0bd241489b40b601a1262d16
+MISC metadata.xml 372 SHA256 c79517f1436518a816ff7335e5e342411b5ce9a2e1ef2279ecc60c4d5e2fa233 SHA512 3ecb379e314ff3f9c745b61707c6df0a912b1466bd56abeebdba0ee138e14ee331fcd61acb3c5b64ace4daa42cbaaec8331cc83d6ae5d0bdc1fa5a69a258ef17 WHIRLPOOL 67ce77734c8d88994c73eee383689f0e6ed7fc2dfe936b3866ec52cb791b6b1d9ac7eaf9871ac6617c507b73738ded310a3a35eb1772ec307b3802e9dc5a6ac6
diff --git a/xfce-base/thunar/metadata.xml b/xfce-base/thunar/metadata.xml
new file mode 100644
index 000000000000..d844c26059c6
--- /dev/null
+++ b/xfce-base/thunar/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>xfce@gentoo.org</email>
+    <name>XFCE Team</name>
+  </maintainer>
+  <use>
+    <flag name='trash-panel-plugin'>Build the trash status indicator plugin for
+      the XFCE panel</flag>
+  </use>
+</pkgmetadata>
diff --git a/xfce-base/thunar/thunar-1.6.10-r1.ebuild b/xfce-base/thunar/thunar-1.6.10-r1.ebuild
new file mode 100644
index 000000000000..de2ff4b76fec
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.6.10-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit virtualx xfconf
+
+MY_P=${P/t/T}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 ia64 ~mips ppc ppc64 sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus debug exif libnotify pcre test udisks +xfce_plugins_trash"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30:=
+	>=x11-libs/gdk-pixbuf-2.14:=
+	>=x11-libs/gtk+-2.24:2=
+	>=xfce-base/exo-0.10:=
+	>=xfce-base/libxfce4ui-4.10:=
+	>=xfce-base/libxfce4util-4.10.1:=
+	>=xfce-base/xfconf-4.10:=
+	dbus? ( >=dev-libs/dbus-glib-0.100:= )
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	udisks? ( virtual/libgudev:= )
+	xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)
+	xfce_plugins_trash? ( ${GVFS_DEPEND} )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="xfce_plugins_trash? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable dbus)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(xfconf_use_debug)
+		$(use_enable exif)
+		$(use_enable pcre)
+		)
+
+	use xfce_plugins_trash || XFCONF+=( --disable-tpa-plugin )
+
+	DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+}
+
+src_test() {
+	Xemake check
+}
diff --git a/xfce-base/thunar/thunar-1.6.12.ebuild b/xfce-base/thunar/thunar-1.6.12.ebuild
new file mode 100644
index 000000000000..c34167b9a8a3
--- /dev/null
+++ b/xfce-base/thunar/thunar-1.6.12.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2-utils virtualx xdg-utils
+
+MY_P=${P^}
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus exif libnotify pcre test +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+COMMON_DEPEND=">=dev-lang/perl-5.6
+	>=dev-libs/glib-2.30:=
+	>=x11-libs/gdk-pixbuf-2.14:=
+	>=x11-libs/gtk+-2.24:2=
+	>=xfce-base/exo-0.10:=
+	>=xfce-base/libxfce4ui-4.10:=
+	>=xfce-base/libxfce4util-4.10.1:=
+	>=xfce-base/xfconf-4.10:=
+	dbus? ( >=dev-libs/dbus-glib-0.100:= )
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( virtual/libgudev:= )"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	dbus? ( ${GVFS_DEPEND} )
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+REQUIRED_USE="trash-panel-plugin? ( dbus )"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_configure() {
+	local myconf=(
+		$(use_enable dbus)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	virtx emake check
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}