gentoo resync : 18.12.2020

3 files changed, 129 insertions, 18 deletions

diff --git a/x11-wm/notion/Manifest b/x11-wm/notion/Manifest
index d14267dd0f1e..28f18b96e7fc 100644
--- a/x11-wm/notion/Manifest
+++ b/x11-wm/notion/Manifest
@@ -3,5 +3,6 @@ AUX notion-3_p2015061300-pkg-config.patch 2533 BLAKE2B 98b1c54fc92067702b77a6f4d
 AUX notion.desktop 208 BLAKE2B 7d138a583a49325901e3c1682c22dbdc1da02b4dcaa2ae6581c66e2676277de1a7b5a87e1c25465cb4ae6beebd7e93ab473e92b3ad6949ad97c833f2293e40da SHA512 3c0a0c5787d77afc94b0f0f9187be5c32374c2dbc51d2d9de3729b2c4e18572d6d8d79a554b017ba33c7276bc2aca8182f93b2d7268f92101385ab6a06f8191f
 DIST notion-3_p2015061300.tar.gz 797057 BLAKE2B 55258bb1d47a1c2506e9cb6654e5d68d69494a749174eaace2a53416ae40cac908b0398400a5a377dbb07618aa800529cbdfc0c7ef946d285681e1dfccfd9c48 SHA512 254be12a8ece555d9f6253d99891bb51214379d0c04b6bf9595b7e5bf9493cb5d2fada37438f89621e7157f9e3647e446b5e173847498ee3608081f006b86679
 EBUILD notion-3_p2015061300-r1.ebuild 2234 BLAKE2B 3ce2236197618615e6f1bc1ce86d964aa855996ef2739c9b357a2c2e5023aec69239ac3a20fd42f7d311777bbb3958910387077c0bb4b89df46a37933d8d4c53 SHA512 ba7058f9a713c7b89d11857614e012ccd69ffe953a7a1f5b0c361cfc93ff4be4c916322a9443d5c09d92766832e09e070baca0f7db24a2e9472363b7f61ef487
-EBUILD notion-9999.ebuild 2190 BLAKE2B 74d2802871b888c0bae7c9a6d90f257847ff1468790d6d74ac1b4b360ed8b422c61418bdf5247e1c91dcc41a4cfd858d414b208b179651464d1dbbdb6bb3f849 SHA512 fb09070ca7e4a0d479e4d539919360073dda1112e6a117aef2b8a3f8735f806de0cd91b9cfad45c9c4635e80d60865bfec8452a45e11fcfb6f9c1e7f3e466c46
+EBUILD notion-3_p2015061300-r100.ebuild 2362 BLAKE2B cde9df6b82ad429e29de3c65417615d44f1237f34fb9fde8f1eb83f644f25e455bd57d17bbeb895c9cf069d6705d4051e00c1fc77f90c1eb4236e814ae53219d SHA512 93ffd486ab64078d7010b949af167b93d16ae97eea741e2ad08627a559f787d72811f1379a68689efe6f9db85578239dc0e5da23d7c949c7edf59be8dc89b9a9
+EBUILD notion-9999.ebuild 2226 BLAKE2B 37f5b955dd35f1e94d00865223e0c5beb538e5e92e7dee608d5fc20b84967bdbb9f774572933be989471ebed5a801345bff1ede813a829b906bd87d2d1d8e6a8 SHA512 b63a100f090dd2a95b754a255657aceae5fd5b8dc0d2e141fd30e9640d2ff4fea2b04860d648eb00cf893255d0bca1e1a34ed5ee10bf7661e173cebc62025979
 MISC metadata.xml 440 BLAKE2B a967115c8e255bb279de1a7a231ea2c45209383ae50bb03ee5e0aeea428e71afdb32ae027286e82820ce3f67849bba51a35ad263c32961de5191d4e053af782e SHA512 e113a6d332d785d2f6fb25d55796d499ccb67978b40130b06be408ae4ba4b9551e35ee928c43c95962e202f12f11ab152073f9d5cbfc16067385c7b34e25dcba
diff --git a/x11-wm/notion/notion-3_p2015061300-r100.ebuild b/x11-wm/notion/notion-3_p2015061300-r100.ebuild
new file mode 100644
index 000000000000..2aee50148789
--- /dev/null
+++ b/x11-wm/notion/notion-3_p2015061300-r100.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..2} )
+
+inherit lua-single toolchain-funcs readme.gentoo-r1
+
+DESCRIPTION="Notion is a tiling, tabbed window manager for the X window system"
+HOMEPAGE="https://notionwm.net/"
+SRC_URI="https://github.com/raboof/${PN}/archive/${PV/_p/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls xinerama +xrandr"
+
+RDEPEND="${LUA_DEPS}
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXext
+	nls? ( sys-devel/gettext )
+	xinerama? ( x11-libs/libXinerama )
+	xrandr? ( x11-libs/libXrandr )"
+DEPEND="${RDEPEND}"
+# luac is called at build time
+BDEPEND="${LUA_DEPS}
+	virtual/pkgconfig"
+
+# mod_xrandr references mod_xinerama
+REQUIRED_USE="${LUA_REQUIRED_USE}
+	xrandr? ( xinerama )"
+
+# needs slingshot,... not in tree
+RESTRICT=test
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3_p2015061300-pkg-config.patch
+)
+
+S=${WORKDIR}/${P/_p/-}
+
+src_prepare() {
+	default
+
+	sed -e "/^CFLAGS/{s: =: +=: ; s:-Os:: ; s:-g::}" \
+		-e "/^LDFLAGS/{s: =: +=: ; s:-Wl,--as-needed::}" \
+		-i system-autodetect.mk || die
+	echo > build/lua-detect.mk
+}
+
+src_configure() {
+	{	echo "CFLAGS += -D_DEFAULT_SOURCE"
+		echo "PREFIX=${EROOT}/usr"
+		echo "DOCDIR=\$(PREFIX)/share/doc/${PF}"
+		echo "ETCDIR=${EROOT}/etc/${PN}"
+		echo "LIBDIR=\$(PREFIX)/$(get_libdir)"
+		echo "VARDIR=${EROOT}/var/cache/${PN}"
+		echo "X11_PREFIX=${EROOT}/usr"
+		echo "STRIPPROG=true"
+		echo "CC=$(tc-getCC)"
+		echo "AR=$(tc-getAR)"
+		echo "RANLIB=$(tc-getRANLIB)"
+		echo "LUA_MANUAL=1"
+		echo "LUA=${LUA}"
+		echo "LUAC=/usr/bin/luac5.1"
+		echo "LUA_LIBS=$(lua_get_LIBS)"
+		echo "LUA_INCLUDES=$(lua_get_CFLAGS)"
+		use nls || echo "DEFINES+=-DCF_NO_LOCALE -DCF_NO_GETTEXT"
+	} > system-local.mk
+
+	if ! use xinerama ; then
+		sed -e 's/mod_xinerama//g' -i modulelist.mk || die
+	fi
+
+	if ! use xrandr ; then
+		sed -e 's/mod_xrandr//g' -i modulelist.mk || die
+		sed -e '/mod_xrandr/d' \
+			-i etc/cfg_defaults.lua || die
+	fi
+}
+
+src_install() {
+	default
+
+	exeinto /etc/X11/Sessions
+	doexe "${FILESDIR}"/notion
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/notion.desktop
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
+
+DOC_CONTENTS="If you want notion to have an ability to view a file based on its
+guessed MIME type you should emerge app-misc/run-mailcap."
diff --git a/x11-wm/notion/notion-9999.ebuild b/x11-wm/notion/notion-9999.ebuild
index 575a0c3ed279..56c03dbb134d 100644
--- a/x11-wm/notion/notion-9999.ebuild
+++ b/x11-wm/notion/notion-9999.ebuild
@@ -1,9 +1,11 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
-inherit eutils git-r3 multilib toolchain-funcs readme.gentoo
+LUA_COMPAT=( lua5-{1..2} )
+
+inherit git-r3 lua-single toolchain-funcs readme.gentoo-r1
 
 DESCRIPTION="Notion is a tiling, tabbed window manager for the X window system"
 HOMEPAGE="https://notionwm.net/"
@@ -14,24 +16,27 @@ SLOT="0"
 KEYWORDS=""
 IUSE="nls xinerama +xrandr"
 
-RDEPEND=">=dev-lang/lua-5.1:0=
+RDEPEND="${LUA_DEPS}
 	x11-libs/libSM
 	x11-libs/libX11
 	x11-libs/libXext
 	nls? ( sys-devel/gettext )
 	xinerama? ( x11-libs/libXinerama )
 	xrandr? ( x11-libs/libXrandr )"
-DEPEND="${RDEPEND}
-		virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+# luac is called at build time
+BDEPEND="${LUA_DEPS}
+	virtual/pkgconfig"
 
 # mod_xrandr references mod_xinerama
-REQUIRED_USE="xrandr? ( xinerama )"
+REQUIRED_USE="${LUA_REQUIRED_USE}
+	xrandr? ( xinerama )"
 
-# needs luaposix,slingshot,... not in tree
+# needs slingshot,... not in tree
 RESTRICT=test
 
 src_prepare() {
-	epatch "${FILESDIR}/${PN}-3_p2015061300-pkg-config.patch"
+	default
 
 	sed -e "/^CFLAGS/{s: =: +=: ; s:-Os:: ; s:-g::}" \
 		-e "/^LDFLAGS/{s: =: +=: ; s:-Wl,--as-needed::}" \
@@ -41,21 +46,21 @@ src_prepare() {
 
 src_configure() {
 	{	echo "CFLAGS += -D_DEFAULT_SOURCE"
-		echo "PREFIX=${ROOT}usr"
+		echo "PREFIX=${EROOT}/usr"
 		echo "DOCDIR=\$(PREFIX)/share/doc/${PF}"
-		echo "ETCDIR=${ROOT}etc/${PN}"
+		echo "ETCDIR=${EROOT}/etc/${PN}"
 		echo "LIBDIR=\$(PREFIX)/$(get_libdir)"
-		echo "VARDIR=${ROOT}var/cache/${PN}"
-		echo "X11_PREFIX=${ROOT}usr"
+		echo "VARDIR=${EROOT}/var/cache/${PN}"
+		echo "X11_PREFIX=${EROOT}/usr"
 		echo "STRIPPROG=true"
 		echo "CC=$(tc-getCC)"
 		echo "AR=$(tc-getAR)"
 		echo "RANLIB=$(tc-getRANLIB)"
 		echo "LUA_MANUAL=1"
-		echo "LUA=\$(BINDIR)/lua"
-		echo "LUAC=\$(BINDIR)/luac"
-		echo "LUA_LIBS=\$(shell pkg-config --libs lua)"
-		echo "LUA_INCLUDES=\$(shell pkg-config --cflags)"
+		echo "LUA=${LUA}"
+		echo "LUAC=luac"
+		echo "LUA_LIBS=$(lua_get_LIBS)"
+		echo "LUA_INCLUDES=$(lua_get_CFLAGS)"
 		use nls || echo "DEFINES+=-DCF_NO_LOCALE -DCF_NO_GETTEXT"
 	} > system-local.mk
 
@@ -79,7 +84,11 @@ src_install() {
 	insinto /usr/share/xsessions
 	doins "${FILESDIR}"/notion.desktop
 
-	readme.gentoo_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
 }
 
 DOC_CONTENTS="If you want notion to have an ability to view a file based on its