gentoo resync : 29.01.2021

1 files changed, 59 insertions, 0 deletions

diff --git a/x11-wm/herbstluftwm/herbstluftwm-0.9.1.ebuild b/x11-wm/herbstluftwm/herbstluftwm-0.9.1.ebuild
new file mode 100644
index 000000000000..cd6435359276
--- /dev/null
+++ b/x11-wm/herbstluftwm/herbstluftwm-0.9.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit cmake python-any-r1 toolchain-funcs
+
+DESCRIPTION="A manual tiling window manager for X"
+HOMEPAGE="https://herbstluftwm.org/"
+SRC_URI="https://herbstluftwm.org/tarballs/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc examples"
+
+DEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+"
+RDEPEND="
+	${DEPEND}
+	app-shells/bash
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-text/asciidoc )
+"
+
+src_prepare() {
+	sed -i \
+		-e '/^install.*LICENSEDIR/d' \
+		-e '/set(DOCDIR / s#.*#set(DOCDIR ${CMAKE_INSTALL_DOCDIR})#' \
+		CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Ensure that 'python3' is in PATH. #765118
+	python_setup
+
+	mycmakeargs=(
+		-DWITH_DOCUMENTATION=$(usex doc)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if ! use examples; then
+		rm -r "${ED}"/usr/share/doc/${PF}/examples || die
+	fi
+}