reinit the tree, so we can have metadata

1 files changed, 39 insertions, 0 deletions

diff --git a/x11-themes/gtk-chtheme/gtk-chtheme-0.3.1-r3.ebuild b/x11-themes/gtk-chtheme/gtk-chtheme-0.3.1-r3.ebuild
new file mode 100644
index 000000000000..2adbbc6017e9
--- /dev/null
+++ b/x11-themes/gtk-chtheme/gtk-chtheme-0.3.1-r3.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils toolchain-funcs
+
+DESCRIPTION="GTK-2.0 Theme Switcher"
+HOMEPAGE="http://plasmasturm.org/programs/gtk-chtheme/"
+SRC_URI="http://plasmasturm.org/programs/gtk-chtheme/${P}.tar.bz2"
+
+IUSE=""
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+LICENSE="GPL-2"
+
+RDEPEND="x11-libs/gtk+:2"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-implicit.patch
+	"${FILESDIR}/${P}-asneeded.patch"  # Fix forced as-needed, bug #248655
+	"${FILESDIR}/${P}-qgtkstyle.patch" # Make it work with qgtkstyle, bug #250504
+)
+
+src_prepare() {
+	# QA: stop Makefile from stripping the binaries
+	sed -i -e "s:strip:true:" "${S}"/Makefile || die "sed failed"
+
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+}