gentoo resync : 22.06.2019

5 files changed, 299 insertions, 0 deletions

diff --git a/x11-misc/arandr/arandr-0.1.10.ebuild b/x11-misc/arandr/arandr-0.1.10.ebuild
new file mode 100644
index 000000000000..6025bf9d41d0
--- /dev/null
+++ b/x11-misc/arandr/arandr-0.1.10.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6} )
+inherit distutils-r1
+
+DESCRIPTION="Another XRandR GUI"
+HOMEPAGE="https://christian.amsuess.com/tools/arandr/"
+SRC_URI="${HOMEPAGE}/files/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/pygobject:3=[${PYTHON_USEDEP}]
+	x11-apps/xrandr
+"
+DEPEND="
+	>=dev-python/docutils-0.6[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local i p
+	# simulate gettext behavior:
+	#  LINGUAS unset => install all
+	#  LINGUAS="" => install none
+	#  LINGUAS="de fr" => install de and fr
+	if [[ -n "${LINGUAS+x}" ]] ; then # if LINGUAS is set
+		for i in $(cd "${S}"/data/po ; for p in *.po ; do echo ${p%.po} ; done) ; do # for every supported language
+			if ! has ${i} ${LINGUAS} ; then # if language is disabled
+				rm data/po/${i}.po || die
+			fi
+		done
+	fi
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	gunzip "${D}"/usr/share/man/man1/{${PN},unxrandr}.1.gz || die
+}
diff --git a/x11-misc/cbatticon/cbatticon-1.6.9.ebuild b/x11-misc/cbatticon/cbatticon-1.6.9.ebuild
new file mode 100644
index 000000000000..c50d042f8226
--- /dev/null
+++ b/x11-misc/cbatticon/cbatticon-1.6.9.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A lightweight and fast battery icon that sits in your system tray"
+HOMEPAGE="https://github.com/ColinJones/cbatticon"
+SRC_URI="https://github.com/ColinJones/cbatticon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libnotify"
+
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/gtk+:3
+	libnotify? ( x11-libs/libnotify )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	strip-linguas -i .
+}
+
+src_compile() {
+	tc-export CC
+	emake \
+		$(usex libnotify WITH_NOTIFY=1 WITH_NOTIFY=0) \
+		V=1 \
+		VERSION="${PF}" \
+		WITH_GTK3=1
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		DOCDIR="/usr/share/doc/${PF}" \
+		LANGUAGES="${LINGUAS}" \
+		V=1 VERSION="${PF}" \
+		install
+
+	dodoc Changelog
+}
diff --git a/x11-misc/gigolo/gigolo-0.4.91-r1.ebuild b/x11-misc/gigolo/gigolo-0.4.91-r1.ebuild
new file mode 100644
index 000000000000..8a8013bbe625
--- /dev/null
+++ b/x11-misc/gigolo/gigolo-0.4.91-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="a frontend to easily manage connections to remote filesystems using GIO/GVfs"
+HOMEPAGE="https://www.uvena.de/gigolo/ https://goodies.xfce.org/projects/applications/gigolo"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.16
+	>=x11-libs/gtk+-3.14:3"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig"
+
+src_prepare() {
+	rm COPYING || die
+	# https://git.xfce.org/apps/gigolo/commit/?id=fb63ddf0fa4ed93789366aefb7a2a2b44e919386
+	sed -i -e 's:gvfs-open:gio open:' src/settings.c || die
+	default
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
diff --git a/x11-misc/mate-notification-daemon/mate-notification-daemon-1.22.0-r1.ebuild b/x11-misc/mate-notification-daemon/mate-notification-daemon-1.22.0-r1.ebuild
new file mode 100644
index 000000000000..b7b3b1ddb731
--- /dev/null
+++ b/x11-misc/mate-notification-daemon/mate-notification-daemon-1.22.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+inherit mate
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="MATE Notification daemon"
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE=""
+
+COMMON_DEPEND="dev-libs/atk
+	>=dev-libs/glib-2.50:2
+	>=sys-apps/dbus-1
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22:2
+	>=x11-libs/libnotify-0.7
+	x11-libs/libX11
+	virtual/libintl
+	>=x11-libs/gtk+-3.22:3
+	>=x11-libs/libwnck-3:3
+	>=media-libs/libcanberra-0.4:0[gtk3]
+	!x11-misc/notify-osd
+	!x11-misc/qtnotifydaemon
+	!x11-misc/notification-daemon"
+
+RDEPEND="${COMMON_DEPEND}"
+
+DEPEND="${COMMON_DEPEND}
+	app-arch/xz-utils
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.50.1
+	sys-devel/gettext:*
+	>=sys-devel/libtool-2.2.6:2
+	virtual/pkgconfig:*"
+
+src_configure() {
+	mate_src_configure
+}
+
+src_install() {
+	mate_src_install
+
+	insinto /usr/share/dbus-1/services
+	doins "${FILESDIR}/org.freedesktop.Notifications.service"
+}
diff --git a/x11-misc/xlockmore/xlockmore-5.57.ebuild b/x11-misc/xlockmore/xlockmore-5.57.ebuild
new file mode 100644
index 000000000000..360f6c9070f1
--- /dev/null
+++ b/x11-misc/xlockmore/xlockmore-5.57.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools flag-o-matic pam
+
+DESCRIPTION="Just another screensaver application for X"
+HOMEPAGE="http://www.sillycycle.com/xlockmore.html"
+SRC_URI="
+	http://www.sillycycle.com/xlock/${P/_alpha/ALPHA}.tar.xz
+	https://dev.gentoo.org/~jer/ax_pthread.m4.xz
+"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="crypt debug gtk imagemagick motif nas opengl pam truetype xinerama xlockrc vtlock"
+
+REQUIRED_USE="
+	|| ( crypt pam )
+	pam? ( !xlockrc )
+	xlockrc? ( !pam )
+"
+RDEPEND="
+	gtk? ( x11-libs/gtk+:2 )
+	imagemagick? ( media-gfx/imagemagick:= )
+	motif? ( >=x11-libs/motif-2.3:0 )
+	nas? ( media-libs/nas )
+	opengl? (
+		virtual/opengl
+		virtual/glu
+		truetype? ( >=media-libs/ftgl-2.1.3_rc5 )
+	)
+	pam? ( virtual/pam )
+	truetype? ( media-libs/freetype:2 )
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXmu
+	x11-libs/libXpm
+	x11-libs/libXt
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.46-freetype261.patch
+	"${FILESDIR}"/${PN}-5.47-CXX.patch
+	"${FILESDIR}"/${PN}-5.47-strip.patch
+)
+S=${WORKDIR}/${P/_alpha/ALPHA}
+
+src_unpack() {
+	unpack ${P/_alpha/ALPHA}.tar.xz
+	xz -cd ${DISTDIR}/ax_pthread.m4.xz > ${S}/ax_pthread.m4 || die
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=()
+
+	if use opengl && use truetype; then
+			myconf=( --with-ftgl )
+			append-flags -DFTGL213
+		else
+			myconf=( --without-ftgl )
+	fi
+
+	myconf+=(
+		$(use_enable pam)
+		$(use_enable xlockrc)
+		$(use_enable vtlock)
+		$(use_with crypt)
+		$(use_with debug editres)
+		$(use_with gtk gtk2)
+		$(use_with imagemagick magick)
+		$(use_with motif)
+		$(use_with nas)
+		$(use_with opengl mesa)
+		$(use_with opengl)
+		$(use_with truetype freetype)
+		$(use_with truetype ttf)
+		$(use_with xinerama)
+		--disable-mb
+		--enable-appdefaultdir=/usr/share/X11/app-defaults
+		--enable-syslog
+		--enable-vtlock
+		--without-esound
+		--without-gtk
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	local DOCS=( README docs/{3d.howto,cell_automata,HACKERS.GUIDE,Purify,Revisions,TODO} )
+	default
+
+	pamd_mimic_system xlock auth
+
+	if use pam; then
+		fperms 755 /usr/bin/xlock
+	else
+		fperms 4755 /usr/bin/xlock
+	fi
+
+	docinto html
+	dodoc docs/xlock.html
+}