gentoo resync : 22.05.2018

2 files changed, 88 insertions, 0 deletions

diff --git a/x11-misc/redshift/Manifest b/x11-misc/redshift/Manifest
index 0c8787d1532d..ddbed4f462cb 100644
--- a/x11-misc/redshift/Manifest
+++ b/x11-misc/redshift/Manifest
@@ -1,3 +1,5 @@
 DIST redshift-1.11.tar.gz 543804 BLAKE2B 9921ed703555fda60c06df9425bf4423ce3891db60f41a1c4c4b4897e2506b8ad79e44f765e49b08db5549406008e12c412c6ecb2a07316cdec4b123fd11ef11 SHA512 bcdb4c120efec3955f4f91f1290db0679e987e25d6610bd90ee8540a96bb11338e36b10680736490ea0b7e9eca5bc195b51767a5badf0b80495dc3da44c4ed8c
+DIST redshift-1.12.tar.gz 659019 BLAKE2B 09339a57fee192e3428ba4387cbea498f2f9f97eb75a418588cdda3289cfa7b7fada4cb299e983e9e6d2ffe3822c8235082e67bdfa542716b6dee9fc853a8dc1 SHA512 6763f6964b577fc146191af1c67a283a60df5bbdd3a74bfc94f66d5f9f3bef8835a479c6ec8a648b650b83a0e245928884a0f628606ace8c3f58d8319d35036f
 EBUILD redshift-1.11-r1.ebuild 1929 BLAKE2B deb30ec58329ba856afbd6176126da5002a49ff62187156788bad54d72f2ec08e410b066992e56be7e86ab6eb3ec704c46fefc0cd9285246bfac050cf68345d8 SHA512 bb1431c1b5fdb038024b9e99f83b49e3336161b6f6a26875f2c1fdd43dde30607fbdbbefbcd56b1eb614080268af8fbccb156a1ae303683f39d620e809a0c6ca
+EBUILD redshift-1.12.ebuild 1932 BLAKE2B 52f33b9630f4d82963c5399a3b3ec4f8d0b978731e2b30df3bebff41c521a490a12b0c41b8c0defc9f6180e70231286a8eeb1c76e448f8543b891e5cda5dd10d SHA512 a6882157a309e4f06917b0c2ecfa80bf810dd1312e06b9c08ab746e7041e257700a94b51b94d3f9b4dafc8e3a45a52585b87ce6322628543ec9751b0f6272060
 MISC metadata.xml 545 BLAKE2B db060df8f3a667a05c9517ed4181b722e4c2f987d7f5aa0085e3d8adf8a0d652fee0ca6901fcab4e75344f3337df4eb1ea15c7555fa2034709c185049155cd06 SHA512 5eb06d120a80deb3d70b3007a4bc8983b276cfb87a5471ca062675770e1e575e29e5b28562e53521976c9ba7c4cd6c95aee7fffb56aa2b1faaed098de42a2bc3
diff --git a/x11-misc/redshift/redshift-1.12.ebuild b/x11-misc/redshift/redshift-1.12.ebuild
new file mode 100644
index 000000000000..e7b003af9f8a
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.12.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+inherit systemd autotools eutils gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="ayatana geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+	ayatana? ( dev-libs/libappindicator:3 )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--disable-apparmor \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+	fi
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}