gentoo resync : 20.02.2019

2 files changed, 87 insertions, 0 deletions

diff --git a/x11-misc/redshift/Manifest b/x11-misc/redshift/Manifest
index d5c9593b04b7..235bf80204c0 100644
--- a/x11-misc/redshift/Manifest
+++ b/x11-misc/redshift/Manifest
@@ -1,4 +1,5 @@
 DIST redshift-1.12.tar.gz 659019 BLAKE2B 09339a57fee192e3428ba4387cbea498f2f9f97eb75a418588cdda3289cfa7b7fada4cb299e983e9e6d2ffe3822c8235082e67bdfa542716b6dee9fc853a8dc1 SHA512 6763f6964b577fc146191af1c67a283a60df5bbdd3a74bfc94f66d5f9f3bef8835a479c6ec8a648b650b83a0e245928884a0f628606ace8c3f58d8319d35036f
 EBUILD redshift-1.12-r1.ebuild 1944 BLAKE2B a3d87bb5fb5835f3476e9e2e8ae5584de15a38aaa53d1133e03bac9047c0f9d7a0d3ee6d66ec7370718b635c6d2af366bc2d7ff90696f785da16b12ea39b0b1f SHA512 750df3819a7d20bbbad2a27caa9385c86f3d1db9e934661977930805c389b8dcb9dfc62e888aa7a2f1a2115dc50943de667a55799498190287422c895beaf6b3
+EBUILD redshift-1.12-r2.ebuild 1946 BLAKE2B d0762f2d3c559d6356a3161ef76f685a6cc326aeec93ca907939d4d8cba21c81be0a3fe626fcd40294d0c9b3f79f139df3be05fe73f53866383f21210b3b6506 SHA512 a217ada5841b968eeb1005d884ab39712fa07fe1970f40eef2e8117ef7d981a4a71dbdc1ee472f4a8d7fdc13cc46de6f0cb83da4b062e84b38ac066ced9ddc9f
 EBUILD redshift-1.12.ebuild 1930 BLAKE2B 0e03e5e7ab1fc0824597fee61d33221796920c2f8a41bf7714f7fc916e9efdb4828a72010062de7d41f4f6e71782eb195e54602e34431167e3170b8f15222b15 SHA512 4e5dacc4c9b84fa6f4103f0e37bb8fbe0607859b3216ba6fc3b858ca9eeedcd92d7a4f650bc68f4fcd953d06d4b72b723ae11d73f7570e86ac16e46bdc0e446d
 MISC metadata.xml 545 BLAKE2B db060df8f3a667a05c9517ed4181b722e4c2f987d7f5aa0085e3d8adf8a0d652fee0ca6901fcab4e75344f3337df4eb1ea15c7555fa2034709c185049155cd06 SHA512 5eb06d120a80deb3d70b3007a4bc8983b276cfb87a5471ca062675770e1e575e29e5b28562e53521976c9ba7c4cd6c95aee7fffb56aa2b1faaed098de42a2bc3
diff --git a/x11-misc/redshift/redshift-1.12-r2.ebuild b/x11-misc/redshift/redshift-1.12-r2.ebuild
new file mode 100644
index 000000000000..a027c4ed7203
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.12-r2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+
+inherit systemd autotools eutils gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="ayatana geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	ayatana? ( dev-libs/libappindicator:3[introspection] )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--disable-apparmor \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+	fi
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}