gentoo resync : 18.11.2019

1 files changed, 56 insertions, 0 deletions

diff --git a/x11-misc/libinput-gestures/libinput-gestures-2.48.ebuild b/x11-misc/libinput-gestures/libinput-gestures-2.48.ebuild
new file mode 100644
index 000000000000..2f4a08da79af
--- /dev/null
+++ b/x11-misc/libinput-gestures/libinput-gestures-2.48.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5..7} )
+
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="Actions gestures on your touchpad using libinput"
+HOMEPAGE="https://github.com/bulletmark/libinput-gestures"
+if [[ ${PV} == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/bulletmark/${PN}.git"
+else
+	SRC_URI="https://github.com/bulletmark/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/libinput-1.8.0
+	x11-misc/wmctrl
+	x11-misc/xdotool"
+DEPEND=">=dev-libs/libinput-1.8.0
+	dev-util/desktop-file-utils"
+
+src_prepare() {
+	default
+
+	# Fix docdir installation path
+	sed '/^DOCDIR/s@$NAME@${PF}@' -i libinput-gestures-setup || die
+}
+
+src_test() { :; }
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	elog "You must be in the input group to read the touchpad device."
+
+	if ! has_version x11-libs/gtk+:3 ; then
+		elog "${PN}-setup script supports Gnome 3 via x11-libs/gtk+:3."
+	fi
+	if ! has_version kde-plasma/kde-cli-tools:5 ; then
+		elog "${PN}-setup script supports Plasma 5 via kde-plasma/kde-cli-tools:5."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}