gentoo auto-resync : 24:01:2023 - 18:57:53

2 files changed, 86 insertions, 0 deletions

diff --git a/x11-misc/gammastep/Manifest b/x11-misc/gammastep/Manifest
index c05cb68eba9d..c9d7e67ec2a4 100644
--- a/x11-misc/gammastep/Manifest
+++ b/x11-misc/gammastep/Manifest
@@ -1,3 +1,4 @@
 DIST gammastep-v2.0.9.tar.bz2 540120 BLAKE2B cfc29b157ad2dbd3d6bb0ac4bdb26c958ba07cad3e817931c2ee4c2e4d15c157b7c0b8b891869ddcc2cdfc39c1d52afb8437991ae60501afee84500e1f28c694 SHA512 d8b23e5890d6135cef79057408e1b7c1dbc36444dfbfaf7c80a3f36c46df19eaded1829c2cd52365413779cc752d0911a44669b5abce16d7e266b92b15c035fb
+EBUILD gammastep-2.0.9-r1.ebuild 1942 BLAKE2B 45af25c0aedcc5e2e0924e058302e05d6dba29115675f747ffe7581e674b81b468e0bf124782faa9852a8a6111ce7b6f4289bf69c05ba57ccb00ba17e50c0c1f SHA512 4d7077c761ebb27b8047bc50a20dadae056c9183892f15f3ecc72b93cbb40ec3e197dc8e22b5e436cb34062680f0a3eb8b4802324a9f7f2cbcc71f5d0abb024c
 EBUILD gammastep-2.0.9.ebuild 1951 BLAKE2B dc03e43cbca16e98165aa5d8110d34c7a495b4564eecc668578bac3cecb1ff0828b1e0d496d85fbe2cf29b72f8e2b886f584c68f76a141d457139fbe10da3636 SHA512 b049f991c2d3227ab84cadeb0f97daeff47d769dad35ddd9662681cb6524a08261e40d96ea11c040b3a4a372d76d7b553450abfdffa2941f9ee2f59b3aa38cfc
 MISC metadata.xml 408 BLAKE2B 76e880ceff79cafe0ee71c2b2bab4c2977a43eb15bc2ffb26cf1431b6c9303bd3b95801e501d01134e546e20c0c83239864eb32e4b8bcea0c7eb8191bc191d8b SHA512 dfd49b49ec66241adb4e53941455d4e1df8af068f894748973fcafab0f8e87238fa3d358b222366efb897558dd7f05e67274a11799169470b5ea3d2663b10137
diff --git a/x11-misc/gammastep/gammastep-2.0.9-r1.ebuild b/x11-misc/gammastep/gammastep-2.0.9-r1.ebuild
new file mode 100644
index 000000000000..6024a5b52019
--- /dev/null
+++ b/x11-misc/gammastep/gammastep-2.0.9-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit autotools systemd xdg-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="https://gitlab.com/chinstrap/gammastep"
+SRC_URI="https://gitlab.com/chinstrap/gammastep/-/archive/v${PV}/gammastep-v${PV}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="appindicator geoclue gtk nls wayland"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	appindicator? ( dev-libs/libayatana-appindicator )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}"/${PN}-v${PV}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		$(use_enable nls) \
+		--enable-drm \
+		$(use_enable wayland) \
+		--enable-randr \
+		--enable-vidmode \
+		$(use_enable geoclue geoclue2) \
+		$(use_enable gtk gui) \
+		--enable-apparmor \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)"
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" \
+		PYTHON="${PYTHON}" \
+		pythondir="$(python_get_sitedir)" \
+		-C src/gammastep_indicator install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/gammastep-indicator
+
+		python_foreach_impl python_optimize
+	fi
+
+	insinto /etc/gammastep/
+	newins gammastep.conf.sample config.ini.example
+}
+
+pkg_postinst() {
+	use gtk && xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && xdg_icon_cache_update
+}