gentoo auto-resync : 16:12:2022 - 03:35:12

1 files changed, 54 insertions, 0 deletions

diff --git a/x11-misc/efax-gtk/efax-gtk-3.2.15-r1.ebuild b/x11-misc/efax-gtk/efax-gtk-3.2.15-r1.ebuild
new file mode 100644
index 000000000000..b14cb1e40f45
--- /dev/null
+++ b/x11-misc/efax-gtk/efax-gtk-3.2.15-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A graphical frontend for the 'efax' application"
+HOMEPAGE="http://efax-gtk.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.src.tgz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.10
+	media-libs/tiff:=
+	x11-libs/libX11
+	x11-libs/c++-gtk-utils:0[gtk]
+	x11-libs/gtk+:3
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+DOCS="AUTHORS BUGS ChangeLog README"
+
+src_prepare() {
+	default
+	# Prevent sandbox violation with chown/chgrp and existing spooldir
+	sed -i -e '/ch.*lp.*spooldir/d' efax-gtk-faxfilter/Makefile.in || die
+
+	sed -i \
+		-e '/^Categories/s:Office;::' \
+		${PN}.desktop || die
+}
+
+src_configure() {
+	econf \
+		--with-gtk-version=gtk3
+}
+
+src_install() {
+	default
+	# File collision with net-misc/efax wrt #401221
+	mv "${ED}"/usr/share/man/man1/efax{,-0.9a}.1 || die
+	mv "${ED}"/usr/share/man/man1/efix{,-0.9a}.1 || die
+}
+
+pkg_postinst() {
+	local spooldir="${EROOT}"/var/spool/fax
+	[[ -d ${spooldir} ]] && chown lp:lp "${spooldir}"
+}