reinit the tree, so we can have metadata

1 files changed, 68 insertions, 0 deletions

diff --git a/www-servers/tornado/tornado-4.5.1.ebuild b/www-servers/tornado/tornado-4.5.1.ebuild
new file mode 100644
index 000000000000..23317435e308
--- /dev/null
+++ b/www-servers/tornado/tornado-4.5.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python web framework and asynchronous networking library"
+HOMEPAGE="http://www.tornadoweb.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+CDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/backports-ssl-match-hostname-3.5[${PYTHON_USEDEP}]' 'python2_7' 'python3_4')
+	|| (
+		>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+		(	$(python_gen_cond_dep 'dev-python/twisted-names[${PYTHON_USEDEP}]' 'python2_7')
+			$(python_gen_cond_dep 'dev-python/twisted-web[${PYTHON_USEDEP}]' 'python2_7')
+		)
+	)
+	virtual/python-backports_abc[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+	virtual/python-singledispatch[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+# doc without intersphinx does not build (asyncio error)
+#PATCHES=(
+#	"${FILESDIR}"/4.5.1-drop-intersphinx.patch
+#)
+
+python_compile_all() {
+	use doc && emake -C docs sphinx
+}
+
+python_test() {
+	"${PYTHON}" -m tornado.test.runtests || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r demos/.
+		docompress -x /usr/share/doc/${PF}/examples
+fi
+	distutils-r1_python_install_all
+}