reinit the tree, so we can have metadata

1 files changed, 62 insertions, 0 deletions

diff --git a/www-client/otter/otter-9999.ebuild b/www-client/otter/otter-9999.ebuild
new file mode 100644
index 000000000000..012c8341b636
--- /dev/null
+++ b/www-client/otter/otter-9999.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils cmake-utils git-r3 gnome2-utils xdg-utils
+
+DESCRIPTION="Project aiming to recreate classic Opera (12.x) UI using Qt5"
+HOMEPAGE="http://otter-browser.org/"
+EGIT_REPO_URI="https://github.com/Emdek/otter"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+
+DEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtscript:5
+	dev-qt/qtsql:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+"
+RDEPEND="
+	${DEPEND}
+"
+DOCS=( CHANGELOG CONTRIBUTING.md TODO )
+
+src_prepare() {
+	default
+
+	if [[ -n ${LINGUAS} ]]; then
+		local lingua
+		for lingua in resources/translations/*.qm; do
+			lingua=$(basename ${lingua})
+			lingua=${lingua/otter-browser_/}
+			lingua=${lingua/.qm/}
+			if ! has ${lingua} ${LINGUAS}; then
+				rm resources/translations/otter-browser_${lingua}.qm || die
+			fi
+		done
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+	domenu ${PN}-browser.desktop
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}