gentoo resync : 02.08.2019

2 files changed, 117 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index f6e6ac389fb7..26ca11bdc352 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,3 +1,5 @@
 DIST opera-developer_64.0.3372.0_amd64.deb 66188452 BLAKE2B 46e2f58775cc092887b8c1438c82b4932c83abcbe5a1afce874ff4a06564de5fb118d56c3a1da073762f0090ae8d90b1da0572a8b49f295afff5be702668d16f SHA512 3c9679957726922a2ab44b84ab783140134462249ae2c9f1f082fa58b4f5d25df2be2fca6c46590d070f90ecbf868225f58ab2b0aa4a506994cadf83833a198e
+DIST opera-developer_64.0.3380.0_amd64.deb 65949000 BLAKE2B 41d0f602d3ca6c73de37912d9262c306e8b88a8466c98428762f5840b8d86aac2042bfd398703bf6a10fdb1731fdd731124066afb133736845fe6245b987b327 SHA512 bf1c2082029212cbeae43b9cf7196ea8efef50905e303e6bf1f51a1971ff8956bf2c5458b130e7e16a3f1c86d6ccfb5423bd4c37d2020426f325948f9462d1b9
 EBUILD opera-developer-64.0.3372.0.ebuild 2293 BLAKE2B 6124beabd01bd27eff345855d147c87368eb6753c616cd0e95195daa428bf02f9694ca924162460aa28a30d62fb3fb58fea7bf5f76a72108c97f1d1421cda163 SHA512 d785b798f471e869faa4a92e2b431d1321d10bafc1cda02f4e92d3a70a1ed68f007f0bb68632d9c32980098a4bf0ef7acc812d07bab02fbdeb5c173235421c03
+EBUILD opera-developer-64.0.3380.0.ebuild 2293 BLAKE2B 6124beabd01bd27eff345855d147c87368eb6753c616cd0e95195daa428bf02f9694ca924162460aa28a30d62fb3fb58fea7bf5f76a72108c97f1d1421cda163 SHA512 d785b798f471e869faa4a92e2b431d1321d10bafc1cda02f4e92d3a70a1ed68f007f0bb68632d9c32980098a4bf0ef7acc812d07bab02fbdeb5c173235421c03
 MISC metadata.xml 238 BLAKE2B 72d4053d28bbf82c9a08a88b354321a782501542b5d506fc6d9f4034839f302761124d59445c0414a0fd38b6401cd5fbe06670802abdb1f25c7cb60919ea5d2e SHA512 b0b981ef72f4d295f427f92dc9931553b4fb7a91c8ed63fa1f28bdbe8bc61d6f0943e1217eb7b61b8d85d9685cbe759db49f094a18a1461cb48429affe76d993
diff --git a/www-client/opera-developer/opera-developer-64.0.3380.0.ebuild b/www-client/opera-developer/opera-developer-64.0.3380.0.ebuild
new file mode 100644
index 000000000000..132f88d22363
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-64.0.3380.0.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}